0  BEGIN PGM 10005_DE MM 
1  ;Fraes-Dreh-Werkstück
2  ;
3  ;Rohteildefinition als Zylinder
4  BLK FORM CYLINDER Z R60 L100 DIST+1
5  ;
6  ;Bezugspunkt aktivieren
7  CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+2    ;BEZUGSPUNKT-NUMMER
8  ;
9  ;Drehbearbeitung aussen schruppen
10 ;Werkzeugaufruf Drehwerkzeug Schruppen
11 TOOL CALL "TURN_ROUGH"
12 ;
13 ;Aufruf Unterprogramm Drehmodus
14 CALL LBL "TURN"
15 ;Aufruf Unterprogramm Sichere Position anfahren
16 CALL LBL "SAFE"
17 ;
18 ;Drehsystem anpassen
19 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
20 ;
21 ;Konstante Schnittgeschwindigkeit und
22 ;maximale Drehzahl definieren
23 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
24 ;
25 ;Schwenkachse auf Null fahren und Drehspindel
26 ;einschalten
27 L  A+0 R0 FMAX M303
28 ;
29 ;Plan drehen
30 CYCL DEF 821 ABSATZ PLAN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+0    ;KONTURENDE DURCHMESSER ~
    Q494=+0    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0    ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
31 L  X+122  Y+0 R0 FMAX ;Vorpositionieren
32 L  Z+10 R0 FMAX ;Vorpositionieren
33 L  Z+2 R0 F0.5 M99 ;Starthoehe anfahren und Zyklusaufruf
34 ;
35 ;Laengs drehen
36 CYCL DEF 811 ABSATZ LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+117  ;KONTURENDE DURCHMESSER ~
    Q494=-80   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
37 L  X+122  Y+0 R0 FMAX ;Vorpositionieren
38 L  Z+10 R0 FMAX ;Vorpositionieren
39 L  Z+2 R0 F0.5 M99 ;Starthoehe anfahren und Zyklusaufruf
40 ;
41 ;Absatz drehen
42 CYCL DEF 811 ABSATZ LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+100  ;KONTURENDE DURCHMESSER ~
    Q494=-20   ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.2  ;AUFMASS DURCHMESSER ~
    Q484=+0    ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
43 L  X+119  Y+0 R0 FMAX ;Vorpositionieren
44 L  Z+10 R0 FMAX ;Vorpositionieren
45 L  Z+2 R0 F0.5 M99 ;Starthoehe anfahren und Zyklusaufruf
46 ;
47 ;Werkzeugaufruf Stechdrehwerkzeug axial
48 TOOL CALL "TURN_REC_AX_100-150"
49 ;
50 ;Aufruf Unterprogramm Drehmodus
51 CALL LBL "TURN"
52 ;Aufruf Unterprogramm Sichere Position anfahren
53 CALL LBL "SAFE"
54 ;
55 ;Drehsystem anpassen
56 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
57 ;
58 ;Konstante Schnittgeschwindigkeit und
59 ;maximale Drehzahl definieren
60 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
61 ;
62 ;Schwenkachse auf Null fahren und Drehspindel
63 ;einschalten
64 L  A+0 R0 FMAX M303
65 ;
66 ;Axialer Einstich
67 CYCL DEF 852 STECHDR. ERW. AXIAL ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+85   ;KONTURSTART DURCHMESSER ~
    Q492=+0    ;KONTURSTART Z ~
    Q493=+50   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q495=+0    ;WINKEL FLANKE ~
    Q501=+1    ;TYP ANFANGSELEMENT ~
    Q502=+0.5  ;GROESSE ANFANGSELEMENT ~
    Q500=+0.5  ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL ZWEITE FLANKE ~
    Q503=+1    ;TYP ENDELEMENT ~
    Q504=+0.5  ;GROESSE ENDELEMENT ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
68 L  X+85  Y+0 R0 FMAX ;Vorpositionieren
69 L  Z+10 R0 FMAX ;Vorpositionieren
70 L  Z+2 R0 F0.5 M99 ;Starthoehe anfahren und Zyklusaufruf
71 ;
72 ;Drehbearbeitung Radialer Einstich
73 ;Werkzeugaufruf Stechdrehwerkzeug radial
74 TOOL CALL "TURN_REC_RAD"
75 ;
76 ;Aufruf Unterprogramm Drehmodus
77 CALL LBL "TURN"
78 ;Aufruf Unterprogramm Sichere Position anfahren
79 CALL LBL "SAFE"
80 ;
81 ;Drehsystem anpassen
82 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
83 ;
84 ;Konstante Schnittgeschwindigkeit und
85 ;maximale Drehzahl definieren
86 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
87 ;
88 ;Schwenkachse auf Null fahren und Drehspindel
89 ;einschalten
90 L  A+0 R0 FMAX M303
91 ;
92 ;Kontur drehen
93 CYCL DEF 14.0 KONTUR
94 CYCL DEF 14.1 KONTURLABEL1
95 CYCL DEF 840 STECHDR. KONT. RAD. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
96 L  X+119  Y+0 R0 FMAX ;Vorpositionieren
97 L  Z+10 R0 FMAX ;Vorpositionieren
98 L  Z+2 R0 F0.5 M99 ;Starthoehe anfahren und Zyklusaufruf
99 ;
100 ;Radialer Einstich
101 CYCL DEF 841 STECHDR. EINFACH R. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+105  ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR
102 L  X+119  Y+0 R0 FMAX ;Vorpositionieren
103 L  Z+10 R0 FMAX ;Vorpositionieren
104 L  Z-23 R0 F0.5 M99 ;Starthoehe anfahren und Zyklusaufruf
105 ;
106 ;Fraesbearbeitung Bohrung
107 ;Aufruf Unterprogramm Fraesmodus
108 CALL LBL "MILL"
109 ;
110 ;Werkzeugaufruf Schaftfraeser
111 TOOL CALL "MILL_D20_ROUGH" Z S3000 F700
112 ;
113 L  X+0  Y+0  Z+100 R0 FMAX M3 ;Vorpositionieren
114 ;
115 ;Bohrung fraesen
116 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-60   ;TIEFE ~
    Q206=+500  ;VORSCHUB TIEFENZ. ~
    Q334=+2.5  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+32   ;SOLL-DURCHMESSER ~
    Q342=+0    ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
117 M99 ;Zyklusaufruf
118 ;
119 ;Aufruf Unterprogramm Sichere Position anfahren
120 CALL LBL "SAFE"
121 ;
122 ;Drehbearbeitung innen schruppen
123 ;Werkzeugaufruf Drehwerkzeug Schruppen
124 TOOL CALL "TURN_ROUGH"
125 ;
126 ;Aufruf Unterprogramm Drehmodus
127 CALL LBL "TURN"
128 ;Aufruf Unterprogramm Sichere Position anfahren
129 CALL LBL "SAFE"
130 ;
131 ;Drehsystem anpassen
132 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+1    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
133 ;
134 ;Konstante Schnittgeschwindigkeit und
135 ;maximale Drehzahl definieren
136 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
137 ;
138 ;Schwenkachse auf Null fahren und Drehspindel
139 ;einschalten (M304 da Werkzeug umgekehrt)
140 L  A+0 R0 FMAX M304
141 ;
142 ;Ansatz innen drehen
143 CYCL DEF 821 ABSATZ PLAN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+84   ;KONTURENDE DURCHMESSER ~
    Q494=-5    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
144 L  X+30  Y+0 R0 FMAX ;Vorpositionieren
145 L  Z+2 R0 FMAX M99 ;Startposition anfahren und Zyklusaufruf
146 ;
147 ;Absatz innen drehen
148 CYCL DEF 822 ABSATZ PLAN ERW. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+32   ;KONTURSTART DURCHMESSER ~
    Q492=-5    ;KONTURSTART Z ~
    Q493=+75   ;KONTURENDE DURCHMESSER ~
    Q494=-40   ;KONTURENDE Z ~
    Q495=+0    ;WINKEL PLANFLAECHE ~
    Q501=+0    ;TYP ANFANGSELEMENT ~
    Q502=+1    ;GROESSE ANFANGSELEMENT ~
    Q500=+1    ;RADIUS KONTURECKE ~
    Q496=+0    ;WINKEL UMFANGSFLAECHE ~
    Q503=+2    ;TYP ENDELEMENT ~
    Q504=+1    ;GROESSE ENDELEMENT ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
149 L  X+30  Y+0 R0 FMAX ;Vorpositionieren
150 L  Z-3 R0 FMAX M99 ;Startposition anfahren und Zyklusaufruf
151 L  Z+10 R0 FMAX ;Freifahren
152 ;
153 ;Aufruf Unterprogramm Sichere Position anfahren
154 CALL LBL "SAFE"
155 ;
156 ;Drehbearbeitung aussen schlichten
157 ;Werkzeugaufruf Drehwerkzeug schlichten
158 TOOL CALL "TURN_FINISH"
159 ;
160 ;Aufruf Unterprogramm Drehmodus
161 CALL LBL "TURN"
162 ;
163 ;Aktivieren der Rohteilnachführung
164 ;Rohteil definiert im Unterprogramm Blank
165 FUNCTION TURNDATA BLANK LBL "Blank"
166 ;
167 ;Drehsystem anpassen
168 ;Werkzeug wird angestellt, da Einstich
169 ;gefertigt wird
170 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+90   ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+2    ;ANGESTELLTE BEARB. ~
    Q531=+30   ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=-1    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
171 ;
172 ;Konstante Schnittgeschwindigkeit und
173 ;maximale Drehzahl definieren
174 FUNCTION TURNDATA SPIN VCONST:ON VC:500 S800
175 ;
176 M303
177 ;Kontur schlichten
178 CYCL DEF 14.0 KONTUR
179 CYCL DEF 14.1 KONTURLABEL3
180 CYCL DEF 810 DREHEN KONTUR LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q499=+0    ;KONTUR UMKEHREN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.1  ;AUFMASS DURCHMESSER ~
    Q484=+0.1  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q487=+1    ;EINTAUCHEN ~
    Q488=+0    ;VORSCHUB EINTAUCHEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q506=+0    ;KONTURGLAETTUNG
181 M99 ;Zyklusaufruf
182 ;
183 ;Drehbearbeitung Gewinde drehen
184 ;Werkzeugaufruf Gewindedrehwerkzeug
185 TOOL CALL "TURN_THREAD"
186 ;
187 ;Aufruf Unterprogramm Drehmodus
188 CALL LBL "TURN"
189 ;
190 ;Aufruf Unterprogramm Sichere Position anfahren
191 CALL LBL "SAFE"
192 ;
193 ;Drehsystem anpassen
194 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
195 ;
196 ;Konstante Schnittgeschwindigkeit und
197 ;maximale Drehzahl definieren
198 FUNCTION TURNDATA SPIN VCONST:ON VC:300 SMAX800
199 ;
200 ;Schwenkachse auf Null fahren und Drehspindel
201 ;einschalten
202 L  A+0 R0 FMAX M304
203 ;
204 ;Gewinde drehen
205 CYCL DEF 831 GEWINDE LAENGS ~
    Q471=+0    ;GEWINDELAGE ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q491=+95   ;GEWINDEDURCHMESSER ~
    Q472=+1.5  ;GEWINDESTEIGUNG ~
    Q473=+0    ;GEWINDETIEFE ~
    Q492=+0    ;KONTURSTART Z ~
    Q494=-20   ;KONTURENDE Z ~
    Q474=+0    ;GEWINDEAUSLAUF ~
    Q463=+0.3  ;MAX. SCHNITTTIEFE ~
    Q467=+0    ;ZUSTELLWINKEL ~
    Q468=+1    ;ZUSTELLART ~
    Q470=+0    ;STARTWINKEL ~
    Q475=+1    ;GANGANZAHL ~
    Q476=+2    ;ANZAHL LEERSCHNITTE
206 L  X+98  Y+0 R0 FMAX ;Vorpositionieren
207 L  Z+2 R0 FMAX ;Startposition anfahren
208 M99 ;Zyklusaufruf
209 ;
210 ;Drehbearbeitung Radialer Einstich
211 ;Werkzeugaufruf Stechdrehwerkzeug radial
212 TOOL CALL "TURN_REC_RAD"
213 ;
214 ;Aufruf Unterprogramm Drehmodus
215 CALL LBL "TURN"
216 ;Aufruf Unterprogramm Sichere Position anfahren
217 CALL LBL "SAFE"
218 ;
219 ;Drehsystem anpassen
220 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
221 ;
222 ;Konstante Schnittgeschwindigkeit und
223 ;maximale Drehzahl definieren
224 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
225 ;
226 ;Schwenkachse auf Null fahren und Drehspindel
227 ;einschalten
228 L  A+0 R0 FMAX M303
229 ;
230 ;Drehbearbeitung Einstich radial
231 ;Kontor drehen
232 CYCL DEF 14.0 KONTUR
233 CYCL DEF 14.1 KONTURLABEL4
234 CYCL DEF 840 STECHDR. KONT. RAD. ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q488=+0.1  ;VORSCHUB EINTAUCHEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q507=+0    ;BEARBEITUNGSRICHTUNG ~
    Q508=+0    ;VERSATZBREITE ~
    Q509=+0    ;TIEFENKORREKTUR ~
    Q499=+0    ;KONTUR UMKEHREN
235 L  X+119  Y+0 R0 FMAX ;Vorpositionieren
236 L  Z+10 R0 FMAX ;Vorpositionieren
237 L  Z+2 R0 F0.5 M99 ;Statposition anfahren und Zyklus aufrufen
238 ;
239 ;Aufruf Unterprogramm Fraesmodus
240 CALL LBL "MILL"
241 ;Aufruf Unterprogramm Sichere Position anfahren
242 CALL LBL "SAFE"
243 ;Programmende
244 M30
245 ;
246 ;Unterprogramm Drehmodus
247 LBL "TURN"
248 M140 MB MAX ;Freifahren
249 M145 ;Kinematikverrechnung aufheben
250 FUNCTION MODE TURN ;Drehmodus aktivieren
251 M144 ;Kinematikverrechnung aktivieren
252 M136 ;Vorschub auf mm pro Umdrehung umschalten
253 LBL 0
254 ;
255 ;Unterprogramm Fraesmodus
256 LBL "MILL"
257 M140 MB MAX ;Freifahren
258 M145 ;Kinematikumverrechnung aufheben
259 FUNCTION MODE MILL ;Fraesmodus aktivieren
260 M137 ;Vorschub auf mm pro Min umstellen
261 ;Unterprogrammaufruf Sichere Position anfahren
262 CALL LBL "SAFE"
263 L  C+0  A+0 R0 FMAX ;Schwenkachsen auf Null fahren
264 LBL 0
265 ;
266 ;Unterprogramm Sichere Position anfahren
267 LBL "SAFE"
268 L  X+400  Y+400 R0 FMAX M91 ;Sichere Position !Maschinenabhaengig!
269 LBL 0
270 ;
271 ;Kontur fuer Rohteilnachfuehrung
272 LBL "Blank"
273 L  Z+0  X+0
274 L  Z+0  X+100
275 L  Z-20  X+100
276 L  Z-20  X+116.9997
277 L  Z-23  X+117
278 L  Z-23  X+105
279 L  Z-40  X+105
280 L  Z-40  X+116.9997
281 L  Z-43  X+117
282 L  Z-43  X+100
283 L  Z-56.9063  X+100
284 L  Z-56.9063  X+0
285 L  Z-60  X+117
286 L  Z-60  X+0
287 L  Z-80  X+117
288 L  Z-80  X+119.9997
289 L  Z-100  X+120
290 L  Z-100  X+0
291 L  Z+0
292 LBL 0
293 ;
294 ;Kontur1
295 LBL 1
296 L  X+117  Z-43 RL
297 L  X+100
298 L  Z-56.9063
299 L  X+117  Z-60
300 LBL 0
301 ;
302 ;Kontur3
303 LBL 3
304 L  X+90  Z+0
305 L  X+95
306 RND R2
307 L  Z-20
308 UDC THREAD PITCH1.5 R0.8 DEPTH0.8 BREADTH5 ;Freistich
309 L  X+110
310 LBL 0
311 ;
312 ;Kontur4
313 LBL 4
314 L  X+105  Z-23
315 L  Z-27
316 GRV RADIAL CENTER-31.5 R1 DIAM89 BREADTH9 ANG_WIDTH28.072 RND1 FAR_RND1 ;Einstich
317 L  Z-40
318 LBL 0
319 END PGM 10005_DE MM