0  BEGIN PGM 10010_DE MM 
1  ;Fraes-Dreh-Werkstück
2  ;Das Rohteil entspricht dem Werkstueck,
3  ;welches mit dem Programm 10005_de.h gefertigt
4  ;wurde.
5  ;
6  ;Rohteildefinition als rotationssymetrischer
7  ;Koerper, dessen Kontur im Unterprogramm BLANK
8  ;definiert ist
9  BLK FORM ROTATION Z DIM_D LBL "BLANK"
10 ;
11 ;Bezugspunkt aktivieren
12 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+2    ;BEZUGSPUNKT-NUMMER
13 ;
14 ;Drehbearbeitung aussen schruppen
15 ;Werkzeugaufruf Drehwerkzeug schruppen
16 TOOL CALL "TURN_ROUGH"
17 ;
18 ;Aufruf Unterprogramm Drehmodus
19 CALL LBL "TURN"
20 ;Aufruf Unterprogramm Sichere Position anfahren
21 CALL LBL "SAFE"
22 ;
23 ;Drehsystem anpassen
24 CYCL DEF 800 KOORD.-SYST.ANPASSEN ~
    Q497=+0    ;PRAEZESSIONSWINKEL ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q530=+0    ;ANGESTELLTE BEARB. ~
    Q531=+0    ;ANSTELLWINKEL ~
    Q532=+750  ;VORSCHUB ~
    Q533=+0    ;VORZUGSRICHTUNG ~
    Q535=+3    ;EXZENTERDREHEN ~
    Q536=+0    ;EXZENTR. OHNE STOPP
25 ;
26 ;Konstante Schnittgeschwindigkeit und
27 ;maximale Drehzahl definieren
28 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
29 ;
30 ;Schwenkachse auf Null fahren und Drehspindel
31 ;einschalten
32 L  A+0 R0 FMAX M303
33 ;
34 ;Plan drehen
35 CYCL DEF 821 ABSATZ PLAN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q493=+0    ;KONTURENDE DURCHMESSER ~
    Q494=+0    ;KONTURENDE Z ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q506=+0    ;KONTURGLAETTUNG
36 L  X+122  Y+0 R0 FMAX ;Vorpositionieren
37 L  Z+5 R0 FMAX ;Starthoehe anfahren
38 M99 ;Zyklus aufrufen
39 ;
40 ;Kontur drehen
41 CYCL DEF 14.0 KONTUR
42 CYCL DEF 14.1 KONTURLABEL1
43 CYCL DEF 810 DREHEN KONTUR LAENGS ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q460=+2    ;SICHERHEITS-ABSTAND ~
    Q499=+0    ;KONTUR UMKEHREN ~
    Q463=+3    ;MAX. SCHNITTTIEFE ~
    Q478=+0.3  ;VORSCHUB SCHRUPPEN ~
    Q483=+0.4  ;AUFMASS DURCHMESSER ~
    Q484=+0.2  ;AUFMASS Z ~
    Q505=+0.2  ;VORSCHUB SCHLICHTEN ~
    Q487=+1    ;EINTAUCHEN ~
    Q488=+0    ;VORSCHUB EINTAUCHEN ~
    Q479=+0    ;SCHNITTBEGRENZUNG ~
    Q480=+0    ;GRENZWERT DURCHMESSER ~
    Q482=+0    ;GRENZWERT Z ~
    Q506=+0    ;KONTURGLAETTUNG
44 L  X+122  Y+0 R0 FMAX ;Vorpositionieren
45 L  Z+5 R0 FMAX ;Starthoehe anfahren
46 M99 ;Zyklusaufruf
47 ;
48 ;Fraesbearbeitung Flaechen und Bohrungen
49 ;Aufruf Unterprogramm Fraesmodus
50 CALL LBL "MILL"
51 ;Aufruf Unterprogramm Sichere Position anfahren
52 CALL LBL "SAFE"
53 ;
54 ;Werkzeugaufruf Schaftfraeser
55 TOOL CALL "MILL_D20_ROUGH" Z S3000 F500
56 ;
57 ;Bohrung im Zentrum
58 L  X+0  Y+0  Z+50 R0 FMAX M3 ;Vorpositionieren
59 CYCL DEF 208 BOHRFRAESEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-40   ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q334=+1.5  ;ZUSTELL-TIEFE ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q335=+32   ;SOLL-DURCHMESSER ~
    Q342=+0    ;VORGEB. DURCHMESSER ~
    Q351=+1    ;FRAESART
60 M99 ;Zyklusaufruf
61 ;
62 ;Aufruf Unterprogramm Sichere Position anfahren
63 CALL LBL "SAFE"
64 ;
65 ;Werkzeugaufruf Schaftfraeser
66 TOOL CALL "MILL_D10_ROUGH" Z S12000 F300
67 ;
68 Q50 = 0 ;Aktueller C-Winkel
69 ;
70 ;Wiederholung fuer Einschwenken und Flaechen fraesen
71 LBL 2
72 PLANE SPATIAL SPA+0 SPB+0 SPC+Q50 STAY ;Koordinatensystem auf aktuellen C-Winkel schwenken
73 ;
74 ;Nullpunkt auf Schwenkkante schieben
75 CYCL DEF 7.0 NULLPUNKT
76 CYCL DEF 7.1  X+37
77 ;
78 PLANE RELATIV SPB+60 TURN MB MAX FMAX ;Relativ zum C-Winkel B einschwenken
79 ;
80 ;Flaechen fraesen
81 L  X+12  Y+0  Z+50 R0 FMAX M3 ;Vorpositionieren
82 CYCL DEF 251 RECHTECKTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+28   ;1. SEITEN-LAENGE ~
    Q219=+50   ;2. SEITEN-LAENGE ~
    Q220=+0    ;ECKENRADIUS ~
    Q368=+0    ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+0    ;TASCHENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-12   ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+12   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+0    ;EINTAUCHEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN
83 M99 ;Zyklus aufrufen
84 ;
85 M140 MB MAX ;Freifahren
86 PLANE RESET STAY ;Rechnerisch zurueckschwenken
87 ;Nullpunktverschiebung zuruecksetzen
88 CYCL DEF 7.0 NULLPUNKT
89 CYCL DEF 7.1  X+0
90 CYCL DEF 7.2  Y+0
91 CYCL DEF 7.3  Z+0
92 ;
93 Q50 = Q50 + 60 ;C-Winkel weiterrechnen
94 CALL LBL 2 REP5 ;Wiederholen
95 ;
96 ;Aufruf Unterprogramm Sichere Position anfahren
97 CALL LBL "SAFE"
98 ;
99 ;Physikalisch zurueckschwenken
100 PLANE RESET TURN MB MAX
101 ;
102 ;Eingeschwenkt bohren
103 ;Werkzeugaufruf Bohrer
104 TOOL CALL "DRILL_D8" Z S12000 F300
105 ;
106 Q50 = 0 ;Aktueller C-Winkel
107 ;
108 ;Wiederholung fuer Einschwenken und bohren
109 LBL 3
110 PLANE SPATIAL SPA+0 SPB+0 SPC+Q50 STAY ;Koordinatensystem auf aktuellen C-Winkel schwenken
111 ;
112 ;Nullpunkt auf Schwenkkante schieben
113 CYCL DEF 7.0 NULLPUNKT
114 CYCL DEF 7.1  X+37
115 ;
116 PLANE RELATIV SPB+60 TURN MB MAX FMAX ;Relativ zum C-Winkel B einschwenken
117 ;
118 L  X+12  Y+0  Z+50 R0 FMAX M3 ;Vorpositionieren
119 CYCL DEF 200 BOHREN ~
    Q200=+3    ;SICHERHEITS-ABST. ~
    Q201=-35   ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN
120 M99 ;Zyklusaufruf
121 ;
122 M140 MB MAX ;Freifahren
123 PLANE RESET STAY ;Rechnerisch zurueckschwenken
124 ;Nullpunktverschiebung zuruecksetzen
125 CYCL DEF 7.0 NULLPUNKT
126 CYCL DEF 7.1  X+0
127 CYCL DEF 7.2  Y+0
128 CYCL DEF 7.3  Z+0
129 ;
130 Q50 = Q50 + 60 ;C-Winkel weiterrechnen
131 CALL LBL 3 REP5 ;Wiederholen
132 ;
133 ;Aufruf Unterprogramm Sichere Position anfahren
134 CALL LBL "SAFE"
135 ;
136 ;Physikalisch zurueckschwenken
137 PLANE RESET TURN MB MAX
138 ;
139 ;Programmende
140 M30
141 ;
142 ;
143 ;Unterprogramm Drehmodus
144 LBL "TURN"
145 M140 MB MAX ;Freifahren
146 M145 ;Kinematikverrechnung aufheben
147 FUNCTION MODE TURN ;Drehmodus aktivieren
148 M144 ;Kinematikverrechnung aktivieren
149 M136 ;Vorschub auf mm pro Umdrehung umschalten
150 LBL 0
151 ;
152 ;Unterprogramm Fraesmodus
153 LBL "MILL"
154 M140 MB MAX ;Freifahren
155 M145 ;Kinematikverrechnung aufheben
156 FUNCTION MODE MILL ;Fraesmodus aktivieren
157 M137 ;Vorschub auf mm pro Min umstellen
158 ;Unterprogrammaufruf Sichere Position anfahren
159 CALL LBL "SAFE"
160 L  C+0  A+0 R0 FMAX ;Schwenkachsen auf Null fahren
161 LBL 0
162 ;
163 ;Unterprogramm Sichere Position anfahren
164 LBL "SAFE"
165 L  X+400  Y+400 R0 FMAX M91 ;Sichere Position !Maschinenabhaengig!
166 LBL 0
167 ;
168 LBL 1 ;Beschreibung Kontur
169 L  Z+0  X+80
170 L  Z-17.32  X+100
171 L  Z-28.0925  X+100
172 L  Z-33  X+117
173 LBL 0
174 ;
175 ;Beschreibung Rohteil
176 LBL "BLANK"
177 L  X+0  Z+2
178 L  X+120
179 L  Z-38
180 L  Z-38  X+117
181 L  Z-41.0937  X+100
182 L  Z-55  X+100
183 L  Z-55  X+108.9998
184 L  Z-55.5  X+110
185 L  Z-57.5  X+110
186 L  Z-58  X+109
187 L  Z-58  X+105
188 L  Z-61.2192  X+105
189 CT  Z-62.1894  X+103.4851
190 L  Z-63.8106  X+90.5146
191 CT  Z-64.7808  X+88.9997
192 L  Z-68.2192  X+88.9997
193 CT  Z-69.1894  X+90.5146
194 L  Z-70.8106  X+103.4851
195 CT  Z-71.7808  X+105
196 L  Z-75  X+105
197 L  Z-75  X+108.9998
198 L  Z-75.5  X+110
199 L  Z-77.5  X+110
200 L  Z-78  X+109
201 L  Z-78  X+92.7
202 L  Z-81.2081  X+92.7
203 L  Z-83.2  X+95
204 L  Z-96  X+95
205 CT  Z-98  X+91
206 L  Z-98  X+85
207 L  Z-93
208 L  X+75
209 L  Z-58
210 L  X+32
211 L  Z-38
212 L  X+0
213 L  Z+2
214 LBL 0
215 END PGM 10010_DE MM