0  BEGIN PGM 1020_DE MM 
1  ;Programm zur Definition eines Punktemusters
2  ;in Form von Gitterlinien.
3  ;Für die Bearbeitung wird an den errechneten
4  ;Positionen ein Bearbeitungszyklus aufgerufen.
5  ;In diesem Programm ein Bohrzyklus. Nach der
6  ;Definition aller benötigten Parameter, des
7  ;Werkzeugs und des Bearbeitungszyklus wird ein
8  ;Unterprogramm aufgerufen, in dem die
9  ;einzelnen Positionen berechnet und
10 ;angefahren werden und der Zyklus
11 ;abgearbeitet wird.
12 ;
13 ;Eingabe Parameter
14 FN 0: Q1 =+10 ;STARTPUNKT IN DER X-ACHSE
15 FN 0: Q2 =+10 ;STARTPUNKT IN DER Y-ACHSE
16 FN 0: Q3 =+9 ;ABSTAND DER BEAREITUNGEN IN X
17 FN 0: Q4 =+12 ;ABSTAND DER BEARBEITUNGEN IN Y
18 FN 0: Q5 =+10 ;ANZAHL DER BEARBEITUNGEN IN X
19 FN 0: Q6 =+7 ;ANZAHL DER BEARBEITUNGEN IN Y
20 FN 0: Q7 =+5 ;ROTATION
21 FN 0: Q8 =+2 ;SICHERHEITSABSTAND
22 ;Parametereingabe Ende
23 ;
24 BLK FORM 0.1 Z X+0 Y+0 Z-25
25 BLK FORM 0.2  X+100  Y+100  Z+0
26 ;
27 ;Werkzeugaufruf Bohrer
28 TOOL CALL 227 Z S1000
29 ;
30 ;Definition Bearbeitungszyklus
31 CYCL DEF 1.0 TIEFBOHREN
32 CYCL DEF 1.1 ABSTQ8
33 CYCL DEF 1.2 TIEFE-20
34 CYCL DEF 1.3 ZUSTLG10
35 CYCL DEF 1.4 V.ZEIT0
36 CYCL DEF 1.5 F100
37 ;
38 CALL LBL 1 ;Aufruf Unterprogramm Positionen
39 ;
40 ;Freifahren und Programmende
41 L  Z+50 R0 FMAX M2
42 ;
43 LBL 1
44 FN 0: Q21 =+0 ;Aktuelle Position in der X-Achse
45 FN 0: Q22 =+0 ;Aktuelle Position in der Y-Achse
46 FN 0: Q25 =+0 ;Aktuelle Spalte
47 FN 0: Q26 =+0 ;Aktuelle Zeile
48 FN 0: Q23 =+Q3 ;X-Schrittweite
49 ;Nullpunkt auf erste Position verschieben
50 CYCL DEF 7.0 NULLPUNKT
51 CYCL DEF 7.1  X+Q1
52 CYCL DEF 7.2  Y+Q2
53 ;Rotation setzen
54 CYCL DEF 10.0 DREHUNG
55 CYCL DEF 10.1  ROT+Q7
56 LBL 2 ;Position anfahren
57 L  X+Q21  Y+Q22 R0 F9999 M3 ;Position anfahren
58 L  Z+Q8 R0 F9999 M99 ;Auf Sicherheitsabstand fahren und Zyklus aufrufen
59 LBL 3 ;Neue Position berechnen
60 FN 1: Q21 =+Q21 + +Q23 ;X-Schritt
61 FN 1: Q25 =+Q25 + +1 ;Spalte weiterzaehlen
62 FN 12: IF +Q25 LT +Q5 GOTO LBL 2
63 FN 0: Q25 =+0 ;Reset Spaltenzaehler
64 FN 1: Q26 =+Q26 + +1 ;Zeile weiterzaehlen
65 FN 0: Q23 =-Q23 ;X-Schrittweite umkehren
66 FN 1: Q21 =+Q21 + +Q23 ;X-Schritt ausgleichen
67 FN 1: Q22 =+Q22 + +Q4 ;Y-Schritt
68 FN 12: IF +Q26 LT +Q6 GOTO LBL 2
69 ;Nullpunkt und Rotation zuruecksetzen
70 CYCL DEF 7.0 NULLPUNKT
71 CYCL DEF 7.1  X+0
72 CYCL DEF 7.2  Y+0
73 CYCL DEF 10.0 DREHUNG
74 CYCL DEF 10.1  ROT+0
75 LBL 0
76 END PGM 1020_DE MM