0  BEGIN PGM 1065_DE MM 
1  ;Programm, um an verschiedenen Positionen
2  ;zu zentrieren, ein Pilotbohrung zu erstellen
3  ;und diese dann tiefer zu bohren.
4  ;Die Positionen und weitere Bohrparameter
5  ;sind in einer Tabelle gespeichert.
6  ;
7  BLK FORM 0.1 Z X+0 Y+0 Z-100
8  BLK FORM 0.2  X+100  Y+100  Z+0
9  ;
10 ; Tabelle mit Bohrparametern definieren
11 FN 26: TABOPEN 10651_de.tab
12 ;
13 ;Werkzeugaufruf Zentrierbohrer
14 TOOL CALL 203 Z S2000
15 ;
16 CYCL DEF 203 UNIVERSAL-BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-3    ;TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q212=+0    ;ABNAHMEBETRAG ~
    Q213=+0    ;ANZ. SPANBRUECHE ~
    Q205=+0    ;MIN. ZUSTELL-TIEFE ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q208=+30000 ;VORSCHUB RUECKZUG ~
    Q256=+0.2  ;RZ BEI SPANBRUCH
17 ;
18 ;Zu verwendende Zeilen der Tabelle definieren
19 FN 0: Q51 =+0 ;STARTZEILE
20 FN 0: Q52 =+4 ;WEITERE ZEILEN
21 ;
22 CALL LBL 12
23 ;
24 STOP
25 ;
26 ;Werkzeugaufruf Bohrer für Pilotbohrung
27 TOOL CALL 227 Z S2000
28 ;
29 ;Zu aendernde Parameter aus dem Bohrzyklus definieren
30 FN 0: Q201 =-10 ;Neue Tiefe
31 ;
32 CALL LBL 12
33 ;
34 STOP
35 ;
36 ;Werkzeugaufruf fuer das Tiefbohren
37 TOOL CALL 226 Z
38 ;
39 ;Parameterdefinition für das Tiefbohren
40 FN 0: Q1 =+0 ;Oberkante
41 FN 0: Q2 =+0 ;Vorbohrtiefe
42 FN 0: Q3 =-10 ;Spaenefoerderhoehe
43 FN 0: Q4 =+1000 ;Vorschub zum Einfahren
44 FN 0: Q5 =+200 ;Vorschub zum Bohren
45 FN 0: Q6 =+2000 ;Drehzahl
46 FN 0: Q7 =+5 ;Zustellung
47 FN 0: Q8 =+0 ;Tiefe
48 FN 0: Q9 =+0.5 ;Verweilzeit
49 FN 0: Q10 =+1 ;Spanbruchwert
50 FN 0: Q11 =+2 ;Sicherheitswert 1 (Inkremental)
51 FN 0: Q12 =+30 ;Sicherheitswert 2 (Inkremental)
52 FN 0: Q13 =+5 ;Anzahl der Zustellungen
53 ;
54 ;PGM 10652_de.h als Zyklus definieren
55 CYCL DEF 12.0 PGM CALL
56 CYCL DEF 12.1 PGM 10652_de.h
57 ;
58 CALL LBL 12
59 ;
60 ;Freifahren und Programmende
61 L  X+0  Y+0  Z+100 FMAX M2
62 ;
63 ;Positionen anfahren
64 LBL 12
65 Q61 = Q51 ;Tabellenzeile der ersten Position definieren
66 LBL 11
67 CALL LBL 10
68 FN 1: Q61 =+Q61 + +1 ;Tabellenzeile weiterrechnen
69 CALL LBL 11 REPQ52
70 LBL 0
71 ;
72 ;Lesebefehle, Position anfahren und Zyklus aufrufen
73 LBL 10
74 FN 28: TABREAD Q41 =Q61 /"X"
75 FN 28: TABREAD Q42 =Q61 /"Y"
76 FN 28: TABREAD Q1 =Q61 /"Z"
77 FN 28: TABREAD Q8 =Q61 /"Tiefe"
78 FN 28: TABREAD Q45 =Q61 /"Abst"
79 FN 28: TABREAD Q46 =Q61 /"Vorschub"
80 FN 28: TABREAD Q47 =Q61 /"Sicherehoehe"
81 L  X+Q41  Y+Q42 R0 FMAX M13 M99
82 LBL 0
83 END PGM 1065_DE MM