0  BEGIN PGM 13_002_2_DE MM 
1  ;Programm um die Vorderseite des
2  ;Uhrengehaeuses zu bearbeiten.
3  ;Die Werkstueckschieflage und die
4  ;Bezugspunkte in X und Y kann man
5  ;ueber die Bohrungen, die von der
6  ;Rueckseite durchgebohrt wurden,
7  ;ermitteln.
8  ;
9  BLK FORM 0.1 Z X-49 Y+0 Z-38
10 BLK FORM 0.2  X+49  Y+85  Z+5
11 ;
12 ;Schwenken und Nullpunkt zuruecksetzen
13 CALL LBL "RESET"
14 ;
15 ;Werkzeugaufruf fuer Planflaeche,
16 ;Absatz und Kreistasche
17 TOOL CALL 11 Z S9550 F2000
18 L  Z+100 R0 FMAX M3
19 ;
20 ;Planflaeche bearbeiten
21 CYCL DEF 233 PLANFRAESEN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q389=+4    ;FRAESSTRATEGIE ~
    Q350=+1    ;FRAESRICHTUNG ~
    Q218=+100  ;1. SEITEN-LAENGE ~
    Q219=+100  ;2. SEITEN-LAENGE ~
    Q227=+5    ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q369=+0.2  ;AUFMASS TIEFE ~
    Q202=+5    ;MAX. ZUSTELL-TIEFE ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q347=+0    ;1.BEGRENZUNG ~
    Q348=+0    ;2.BEGRENZUNG ~
    Q349=+0    ;3.BEGRENZUNG ~
    Q220=+0    ;ECKENRADIUS ~
    Q368=+0    ;AUFMASS SEITE ~
    Q338=+0    ;ZUST. SCHLICHTEN
22 L  X-50  Y-7.5 R0 FMAX M99
23 ;
24 ;Absatz fraesen
25 CYCL DEF 233 PLANFRAESEN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q389=+2    ;FRAESSTRATEGIE ~
    Q350=+1    ;FRAESRICHTUNG ~
    Q218=+98   ;1. SEITEN-LAENGE ~
    Q219=-67   ;2. SEITEN-LAENGE ~
    Q227=+0    ;STARTPUNKT 3. ACHSE ~
    Q386=-14   ;ENDPUNKT 3. ACHSE ~
    Q369=+0.2  ;AUFMASS TIEFE ~
    Q202=+5    ;MAX. ZUSTELL-TIEFE ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q347=-2    ;1.BEGRENZUNG ~
    Q348=+0    ;2.BEGRENZUNG ~
    Q349=+0    ;3.BEGRENZUNG ~
    Q220=+0    ;ECKENRADIUS ~
    Q368=+0.2  ;AUFMASS SEITE ~
    Q338=+0    ;ZUST. SCHLICHTEN
26 L  X-49  Y+85 R0 FMAX M99
27 ;
28 ;Kreistasche fraesen
29 L  X+0  Y+50 R0 FMAX
30 CYCL DEF 252 KREISTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+60   ;KREISDURCHMESSER ~
    Q368=+0.2  ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-5    ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0.2  ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=-14   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN
31 M99
32 L  Z+100 R0 FMAX M5 ;Freifahren
33 ;
34 ;Werkzeugaufruf zum Vorfraesen der
35 ;Kontur
36 TOOL CALL 16 Z S2000 F300
37 L  Z+100 R0 FMAX M3
38 CYCL DEF 14.0 KONTUR
39 CYCL DEF 14.1 KONTURLABEL1
40 CYCL DEF 25 KONTUR-ZUG ~
    Q1=-7    ;FRAESTIEFE ~
    Q3=+0.5  ;AUFMASS SEITE ~
    Q5=-14   ;KOOR. OBERFLAECHE ~
    Q7=+50   ;SICHERE HOEHE ~
    Q10=-5    ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q15=+1    ;FRAESART
41 M99
42 L  Z+100 R0 FMAX M5
43 ;
44 ;Werkzeugaufruf fuer die Schraege, die
45 ;Taschen und zum Schlichten der
46 ;Kontur
47 TOOL CALL 5 Z S14000 F2500
48 ;
49 ;Freifahren auf sichere Position
50 CALL LBL "S-POS"
51 ;
52 ;Nullpunkt verschieben
53 CYCL DEF 7.0 NULLPUNKT
54 CYCL DEF 7.1  Y+18
55 CYCL DEF 7.2  Z-14
56 ;
57 ;Bearbeitungsebene Schwenken
58 PLANE SPATIAL SPA-45 SPB+0 SPC+0 TURN MB MAX FMAX
59 L  Z+100 R0 FMAX M3
60 L  X-55  Y+0 R0 FMAX
61 CYCL DEF 251 RECHTECKTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+110  ;1. SEITEN-LAENGE ~
    Q219=+22   ;2. SEITEN-LAENGE ~
    Q220=+5    ;ECKENRADIUS ~
    Q368=+0.2  ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+4    ;TASCHENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-10   ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0.2  ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+5    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+10   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+2    ;EINTAUCHEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN
62 M99
63 L  Z+100 R0 FMAX
64 ;
65 ;Schwenken und Nullpunkt zuruecksetzen
66 CALL LBL "RESET"
67 ;
68 ;Rechtecktaschen fraesen
69 L  Z+100 R0 FMAX
70 CYCL DEF 251 RECHTECKTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+12   ;1. SEITEN-LAENGE ~
    Q219=+30   ;2. SEITEN-LAENGE ~
    Q220=+0    ;ECKENRADIUS ~
    Q368=+0.2  ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+0    ;TASCHENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-5    ;TIEFE ~
    Q202=+3    ;ZUSTELL-TIEFE ~
    Q369=+0.2  ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+5    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=-21   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+2    ;EINTAUCHEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN
71 L  X-41  Y+66 R0 FMAX M99
72 L  X+41  Y+66 R0 FMAX M99
73 ;
74 ;Kontur schlichten
75 CYCL DEF 14.0 KONTUR
76 CYCL DEF 14.1 KONTURLABEL1
77 CYCL DEF 25 KONTUR-ZUG ~
    Q1=-7    ;FRAESTIEFE ~
    Q3=+0    ;AUFMASS SEITE ~
    Q5=-14   ;KOOR. OBERFLAECHE ~
    Q7=+50   ;SICHERE HOEHE ~
    Q10=-5    ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q15=+1    ;FRAESART
78 M99
79 L  Z+100 R0 FMAX M5 ;Freifahren
80 ;
81 ;Werkzeugaufruf zum Entgraten
82 TOOL CALL 172 Z S900 F500
83 L  Z+100 R0 FMAX M3
84 ;
85 ;Bohrungen entgraten
86 L  X+0  Y+50 R0 FMAX
87 CYCL DEF 240 ZENTRIEREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q343=+1    ;AUSWAHL DURCHM/TIEFE ~
    Q201=-2    ;TIEFE ~
    Q344=-9    ;DURCHMESSER ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q203=-19   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
88 M99
89 CYCL DEF 240 ZENTRIEREN ~
    Q200=+3    ;SICHERHEITS-ABST. ~
    Q343=+1    ;AUSWAHL DURCHM/TIEFE ~
    Q201=-2    ;TIEFE ~
    Q344=-6    ;DURCHMESSER ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q203=-19   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
90 PATTERN DEF ~
    CIRC1(  X+0  Y+50 D46 START+0 NUM4  Z+0 )
91 CYCL CALL PAT FMAX
92 ;
93 ;Werkzeugaufruf mit DR fuer die Fase
94 TOOL CALL 172 Z S900 F500 DR-4.5
95 ;
96 ;Kreistasche entgraten
97 L  X+0  Y+50 R0 FMAX
98 CYCL DEF 252 KREISTASCHE ~
    Q215=+2    ;BEARBEITUNGS-UMFANG ~
    Q223=+60   ;KREISDURCHMESSER ~
    Q368=+0.1  ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-0.8  ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+1    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=-14   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN
99 M99
100 ;
101 ;Kontur entgraten
102 CYCL DEF 14.0 KONTUR
103 CYCL DEF 14.1 KONTURLABEL1
104 CYCL DEF 25 KONTUR-ZUG ~
    Q1=-2.5  ;FRAESTIEFE ~
    Q3=+0    ;AUFMASS SEITE ~
    Q5=-14   ;KOOR. OBERFLAECHE ~
    Q7=+50   ;SICHERE HOEHE ~
    Q10=-2.3  ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q15=+1    ;FRAESART
105 M99
106 L  Z+100 R0 FMAX M5 ;Freifahren
107 ;
108 ;Werkzeugaufruf zum Anzentrieren
109 TOOL CALL 204 Z S6000 F400
110 L  Z+100 R0 FMAX M3
111 ;
112 ;Zentrierungen auf dem Zifferblatt
113 L  X+0  Y+50 R0 FMAX
114 CYCL DEF 240 ZENTRIEREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q343=+1    ;AUSWAHL DURCHM/TIEFE ~
    Q201=-2    ;TIEFE ~
    Q344=-5    ;DURCHMESSER ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q203=-19   ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
115 CC  X+0  Y+50
116 LP  PR+23  PA+30 FMAX M99
117 LP IPA+30 R0 FMAX M99
118 LP IPA+60 R0 FMAX M99
119 LP IPA+30 R0 FMAX M99
120 LP IPA+60 R0 FMAX M99
121 LP IPA+30 R0 FMAX M99
122 LP IPA+60 R0 FMAX M99
123 LP IPA+30 R0 FMAX M99
124 L  Z+100 R0 FMAX M5 ;Freifahren
125 ;
126 ;Zentrierungen fuer Bohrungen D10
127 ;
128 ;Sichere Position anfahren
129 CALL LBL "S-POS"
130 ;
131 ;Nullpunkt verschieben
132 CYCL DEF 7.0 NULLPUNKT
133 CYCL DEF 7.1  Y+4
134 ;
135 ;Bearbeitungsebene schwenken
136 PLANE SPATIAL SPA-45 SPB+0 SPC+0 TURN MB MAX FMAX
137 L  Z+100 R0 FMAX M3
138 L  X+38  Y+9 R0 FMAX
139 CYCL DEF 240 ZENTRIEREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q343=+1    ;AUSWAHL DURCHM/TIEFE ~
    Q201=-2    ;TIEFE ~
    Q344=-10.5 ;DURCHMESSER ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
140 M99
141 L  X-38 R0 FMAX M99
142 L  Z+100 R0 FMAX M5 ;Freifahren
143 ;
144 ;Schwenken und Nullpunkt zuruecksetzen
145 CALL LBL "RESET"
146 ;
147 ;Werkzeugaufruf bohren Bohrung
148 ;D10
149 TOOL CALL 232 Z S3000 F400
150 ;
151 ;Sichere Position anfahren
152 CALL LBL "S-POS"
153 ;
154 ;Nullpunkt verschieben
155 CYCL DEF 7.0 NULLPUNKT
156 CYCL DEF 7.1  Y+4
157 ;
158 ;Bearbeitungsebene schwenken
159 PLANE SPATIAL SPA-45 SPB+0 SPC+0 TURN MB MAX FMAX
160 L  Z+100 R0 FMAX M3
161 L  X+38  Y+9 R0 FMAX
162 CYCL DEF 200 BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-9    ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q395=+1    ;BEZUG TIEFE
163 M99
164 L  X-38 R0 FMAX M99
165 L  Z+100 R0 FMAX M5 ;Freifahren
166 ;
167 ;Schwenken und Nullpunkt zuruecksetzen
168 CALL LBL "RESET"
169 ;
170 L  Z+100 R0 FMAX M30 ;Freifahren
171 ;
172 ;Unterprogramme
173 ;Kontur
174 LBL 1
175 L  X-65  Y+22 RL
176 L  X-49
177 FL  X-34  AN+28
178 RND R10
179 L  Y+50
180 CC  X+0  Y+50
181 CP  PA+0 DR-
182 FLT  X+34  AN-90
183 FCT DR+ R10
184 FLT  X+49  Y+22  AN-28
185 L  X+65
186 LBL 0
187 ;
188 ;Sichere Position
189 LBL "S-POS"
190 L  Z+135 R0 FMAX M91
191 L  X+175  Y+140 R0 FMAX M91
192 LBL 0
193 ;
194 ;Schwenken zuruecksetzen
195 LBL "RESET"
196 ;Sichere Position anfahren
197 CALL LBL "S-POS"
198 ;Schwenken zuruecksetzen
199 PLANE RESET TURN FMAX
200 ;Nullpunkt zuruecksetzen
201 CYCL DEF 7.0 NULLPUNKT
202 CYCL DEF 7.1  X+0
203 CYCL DEF 7.2  Y+0
204 CYCL DEF 7.3  Z+0
205 LBL 0
206 END PGM 13_002_2_DE MM