0  BEGIN PGM 13_003_1_DE MM 
1  ;NC-Programm zur Bearbeitung des Unterteils
2  ;vom Solitaerspiel.
3  BLK FORM 0.1 Z X-49.5 Y-49.5 Z-25
4  BLK FORM 0.2  X+49.5  Y+49.5  Z+1
5  ;Werkzeugaufruf fuer die Plan- und
6  ;Aussenbearbeitung
7  TOOL CALL 8 Z S9500 F2000
8  L  Z+100 R0 FMAX M3
9  CYCL DEF 232 PLANFRAESEN ~
    Q389=+0    ;STRATEGIE ~
    Q225=-50   ;STARTPUNKT 1. ACHSE ~
    Q226=+50   ;STARTPUNKT 2. ACHSE ~
    Q227=+1    ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+100  ;1. SEITEN-LAENGE ~
    Q219=-100  ;2. SEITEN-LAENGE ~
    Q202=+2    ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
10 M99
11 L  X+0  Y+0 R0 FMAX
12 CYCL DEF 257 KREISZAPFEN ~
    Q223=+99   ;FERTIGTEIL-DURCHM. ~
    Q222=+141  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-20   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=+0    ;STARTWINKEL
13 M99
14 L  X+0  Y+0 R0 FMAX
15 CYCL DEF 257 KREISZAPFEN ~
    Q223=+96   ;FERTIGTEIL-DURCHM. ~
    Q222=+100  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-3    ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=+0    ;STARTWINKEL
16 M99
17 L  Z+100 R0 FMAX M5
18 ;Werkzeugaufruf fuer die Taschenbearbeitung
19 TOOL CALL 4 Z S12000 F1500
20 L  Z+100 R0 FMAX M3
21 CYCL DEF 14.0 KONTUR
22 CYCL DEF 14.1 KONTURLABEL1 /2
23 CYCL DEF 20 KONTUR-DATEN ~
    Q1=-8    ;FRAESTIEFE ~
    Q2=+1    ;BAHN-UEBERLAPPUNG ~
    Q3=+0    ;AUFMASS SEITE ~
    Q4=+0    ;AUFMASS TIEFE ~
    Q5=+0    ;KOOR. OBERFLAECHE ~
    Q6=+2    ;SICHERHEITS-ABST. ~
    Q7=+50   ;SICHERE HOEHE ~
    Q8=+0    ;RUNDUNGSRADIUS ~
    Q9=+1    ;DREHSINN
24 CYCL DEF 22 AUSRAEUMEN ~
    Q10=-5    ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q18=+0    ;VORRAEUM-WERKZEUG ~
    Q19= AUTO ;VORSCHUB PENDELN ~
    Q208=+99999 ;VORSCHUB RUECKZUG ~
    Q401=+100  ;VORSCHUBFAKTOR ~
    Q404=+0    ;NACHRAEUMSTRATEGIE
25 M99
26 L  Z+100 R0 FMAX M5
27 ;Werkzeugaufruf fuer das Zentrieren
28 TOOL CALL 203 Z S5000 F500
29 L  Z+100 R0 FMAX M3
30 L  X+0  Y+0 R0 FMAX
31 CYCL DEF 240 ZENTRIEREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q343=+1    ;AUSWAHL DURCHM/TIEFE ~
    Q201=-2    ;TIEFE ~
    Q344=-4.4  ;DURCHMESSER ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+2    ;2. SICHERHEITS-ABST.
32 CALL LBL "BOHRUNGEN"
33 L  Z+100 R0 FMAX M5
34 ;Werkzeugaufruf fuer das Bohren
35 TOOL CALL 226 Z S3000 F200
36 L  Z+100 R0 FMAX M3
37 CYCL DEF 200 BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-10   ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q395=+0    ;BEZUG TIEFE
38 CALL LBL "BOHRUNGEN"
39 L  Z+100 R0 FMAX M5
40 ;Werkzeugaufruf zum Entgraten der
41 ;Zentrierung und der Konturen
42 TOOL CALL 171 Z S15000 F1000 DR-3
43 L  Z+100 R0 FMAX M3
44 CYCL DEF 14.0 KONTUR
45 CYCL DEF 14.1 KONTURLABEL1
46 CYCL DEF 25 KONTUR-ZUG ~
    Q1=-1.5  ;FRAESTIEFE ~
    Q3=+0    ;AUFMASS SEITE ~
    Q5=+0    ;KOOR. OBERFLAECHE ~
    Q7=+2    ;SICHERE HOEHE ~
    Q10=-5    ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q15=+1    ;FRAESART
47 M99
48 CYCL DEF 14.0 KONTUR
49 CYCL DEF 14.1 KONTURLABEL2
50 CYCL DEF 25 KONTUR-ZUG ~
    Q1=-1.5  ;FRAESTIEFE ~
    Q3=+0    ;AUFMASS SEITE ~
    Q5=+0    ;KOOR. OBERFLAECHE ~
    Q7=+2    ;SICHERE HOEHE ~
    Q10=-5    ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q15=+1    ;FRAESART
51 M99
52 L  X+0  Y+0 R0 FMAX
53 CYCL DEF 257 KREISZAPFEN ~
    Q223=+96   ;FERTIGTEIL-DURCHM. ~
    Q222=+96.1 ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-1.5  ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+2    ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=+0    ;STARTWINKEL
54 M99
55 L  Z+100 R0 FMAX M5
56 M30
57 ;Unterprogramme
58 LBL 1
59 CC  X+0  Y+0
60 LP  PR+46  PA+0 RL
61 CP IPA+360 DR+
62 LBL 0
63 LBL 2
64 L  X+0  Y+35 RL
65 L  X+15
66 RND R5
67 L  Y+15
68 RND R5
69 L  X+35
70 RND R5
71 L  Y-15
72 RND R5
73 L  X+15
74 RND R5
75 L  Y-35
76 RND R5
77 L  X-15
78 RND R5
79 L  Y-15
80 RND R5
81 L  X-35
82 RND R5
83 L  Y+15
84 RND R5
85 L  X-15
86 RND R5
87 L  Y+35
88 RND R5
89 L  X+0
90 LBL 0
91 LBL "BOHRUNGEN"
92 PATTERN DEF ~
    PAT1(  X-30  Y-10 DX+10 DY+10 NUMX7 NUMY3 ROT+0 ROTX+0 ROTY+0  Z+0 )
93 CYCL CALL PAT FMAX
94 PATTERN DEF ~
    PAT1(  X-10  Y+20 DX+10 DY+10 NUMX3 NUMY2 ROT+0 ROTX+0 ROTY+0  Z+0 )
95 CYCL CALL PAT FMAX
96 PATTERN DEF ~
    PAT1(  X-10  Y-30 DX+10 DY+10 NUMX3 NUMY2 ROT+0 ROTX+0 ROTY+0  Z+0 )
97 CYCL CALL PAT FMAX
98 LBL 0
99 END PGM 13_003_1_DE MM