0  BEGIN PGM 2125-DE MM 
1  ;Programm zum erstellen einer Tasche mit der
2  ;der Kontur einer Ellipse
3  BLK FORM 0.1 Z X+0 Y+0 Z-20
4  BLK FORM 0.2  X+100  Y+100  Z+0
5  ;
6  ;Werkzeugaufruf Schaftfraeser D10
7  TOOL CALL 5 Z S5000
8  ;
9  ;Schnittdaten
10 Q50 = 20 ;FRAESTIEFE
11 Q51 = 3 ;ZUSTELLTIEFE
12 Q52 = 2 ;SICHERHEITABSTAND
13 Q53 = 150 ;VORSCHUB TIEFENZUSTELLUNG
14 Q54 = 500 ;VORSCHUB FRAESEN
15 ;
16 ;Parameter fuer Ellipse
17 Q31 = 50 ;GROSSER RADIUS
18 Q32 = 25 ;KLEINER RADIUS
19 Q33 = 1 ;WINKELSCHRITT
20 Q38 = 50 ;MITTELPUNKT ELLIPSE X
21 Q39 = 50 ;MITTELPUNKT ELLIPSE Y
22 Q40 = 45 ;DREHUNG
23 ;***Reset Parameter
24 Q41 = 0 ;RESET WINKELWERT
25 ;
26 ;===========================================
27 CYCL DEF 7.0 NULLPUNKT
28 CYCL DEF 7.1  X+Q38
29 CYCL DEF 7.2  Y+Q39
30 CYCL DEF 10.0 DREHUNG
31 CYCL DEF 10.1  ROT+Q40
32 CYCL DEF 14.0 KONTUR
33 CYCL DEF 14.1 KONTURLABEL1
34 CYCL DEF 20 KONTUR-DATEN ~
    Q1=-Q50  ;FRAESTIEFE ~
    Q2=+1    ;BAHN-UEBERLAPPUNG ~
    Q3=+0    ;AUFMASS SEITE ~
    Q4=+0    ;AUFMASS TIEFE ~
    Q5=+0    ;KOOR. OBERFLAECHE ~
    Q6=+Q52  ;SICHERHEITS-ABST. ~
    Q7=+50   ;SICHERE HOEHE ~
    Q8=+0    ;RUNDUNGSRADIUS ~
    Q9=+1    ;DREHSINN
35 CYCL DEF 22 AUSRAEUMEN ~
    Q10=-Q51  ;ZUSTELL-TIEFE ~
    Q11=+Q53  ;VORSCHUB TIEFENZ. ~
    Q12=+Q54  ;VORSCHUB RAEUMEN ~
    Q18=+0    ;VORRAEUM-WERKZEUG ~
    Q19=+Q53  ;VORSCHUB PENDELN ~
    Q208=+99999 ;VORSCHUB RUECKZUG
36 M3 M99
37 CYCL DEF 7.0 NULLPUNKT
38 CYCL DEF 7.1  X+0
39 CYCL DEF 7.2  Y+0
40 CYCL DEF 10.0 DREHUNG
41 CYCL DEF 10.1  ROT+0
42 ;
43 ;Programmende
44 L  Z+50 R0 FMAX M30
45 ;
46 ;Unterprogramm
47 ;***Konturbeschreibung
48 LBL 1
49 Q42 = COS Q41 * Q31 ;BERECHNUNG NEUER X-WERT
50 Q43 = SIN Q41 * Q32 ;BERECHNUNG NEUER Y-WERT
51 L  X+Q42  Y+Q43 RL
52 Q41 = Q41 + Q33 ;BERECHNUNG NEUER WINKELWERT
53 FN 12: IF +Q41 LT +360 GOTO LBL 1
54 LBL 0
55 END PGM 2125-DE MM