0  BEGIN PGM 2130_DE MM 
1  ;Programm zur Erstellung einer Tasche mit der Kontur eines
2  ;P3G Polygonprofils nach DIN 32711
3  BLK FORM 0.1 Z X+0 Y+0 Z-25
4  BLK FORM 0.2  X+100  Y+100  Z+0
5  ;
6  ;Werkzeugaufruf Schaftfraeser D20
7  TOOL CALL 13 Z S5000
8  ;
9  ;Schnittdaten
10 Q50 = 20 ;FRAESTIEFE
11 Q51 = 3 ;ZUSTELLTIEFE
12 Q52 = 2 ;SICHERHEITABSTAND
13 Q53 = 150 ;VORSCHUB TIEFENZUSTELLUNG
14 Q54 = 500 ;VORSCHUB FRAESEN
15 ;
16 ;Parameter fuer P3G Polygon
17 Q30 = 75 ;GLEICHDICKDURCHMESSER (D1)
18 Q31 = 3.15 ;EXZENTERGROESSE (E)
19 Q36 = 50 ;ZENTRUM VOM POLYGON IN X-ACHSE
20 Q37 = 50 ;ZENTRUM VOM POLYGON IN Y-ACHSE
21 Q38 = 0 ;ROTATION
22 ;Parametereingabe Ende
23 ;===========================================
24 Q35 = 0 ;START FUER WINKELSCHRITT
25 CYCL DEF 7.0 NULLPUNKT
26 CYCL DEF 7.1  X+Q36
27 CYCL DEF 7.2  Y+Q37
28 CYCL DEF 10.0 DREHUNG
29 CYCL DEF 10.1  ROT+Q38
30 CYCL DEF 14.0 KONTUR
31 CYCL DEF 14.1 KONTURLABEL1
32 CYCL DEF 20 KONTUR-DATEN ~
    Q1=-Q50  ;FRAESTIEFE ~
    Q2=+1    ;BAHN-UEBERLAPPUNG ~
    Q3=+0    ;AUFMASS SEITE ~
    Q4=+0    ;AUFMASS TIEFE ~
    Q5=+0    ;KOOR. OBERFLAECHE ~
    Q6=+Q52  ;SICHERHEITS-ABST. ~
    Q7=+50   ;SICHERE HOEHE ~
    Q8=+0    ;RUNDUNGSRADIUS ~
    Q9=+1    ;DREHSINN
33 CYCL DEF 22 AUSRAEUMEN ~
    Q10=-Q51  ;ZUSTELL-TIEFE ~
    Q11=+Q53  ;VORSCHUB TIEFENZ. ~
    Q12=+Q54  ;VORSCHUB RAEUMEN ~
    Q18=+0    ;VORRAEUM-WERKZEUG ~
    Q19=+0    ;VORSCHUB PENDELN ~
    Q208=+99999 ;VORSCHUB RUECKZUG
34 L  X+0  Y+0 R0 FMAX M3 M99
35 CYCL DEF 10.0 DREHUNG
36 CYCL DEF 10.1  ROT+0
37 CYCL DEF 7.0 NULLPUNKT
38 CYCL DEF 7.1  X+0
39 CYCL DEF 7.2  Y+0
40 ;
41 ;Programmende
42 L  Z+50 R0 FMAX M30
43 ;
44 ;Unterprogramm
45 ;Berechnung der Konturpunkte
46 LBL 1
47 Q40 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * COS Q35 - 3 * Q31 * SIN ( 3 * Q35 ) * SIN Q35
48 Q41 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * SIN Q35 + 3 * Q31 * SIN ( 3 * Q35 ) * COS Q35
49 L  X+Q40  Y+Q41 RL
50 Q35 = Q35 + 0.5
51 FN 10: IF +Q35 NE +360.5 GOTO LBL 1
52 LBL 0
53 END PGM 2130_DE MM