0  BEGIN PGM 2145_DE MM 
1  ;NC-Programm, in dem ein SL-Zyklus definiert
2  ;ist. Die Beonderheit ist, dass durch einen
3  ;Q-Parameter ausgewaehlt werden kann, welche
4  ;Unterprogrammnummer als Kontur verwendet
5  ;werden soll.
6  ;Dazu definieren Sie am Programmbeginn einen
7  ;Parameter mit der Nummer des zu verwendenden
8  ;Unterprogramms, im Beispiel 11 oder 12.
9  ;Im Zyklus 14 ist dann die Unterprogramm-
10 ;nummer der Insel und die eines weiteren
11 ;Unterprogramms angegeben. Dieses zweite
12 ;Unterprogramm besteht lediglich aus einem
13 ;CALL LBL mit dem zu Beginn definierten
14 ;Q-Parameter, so dass das ausgewaehlte
15 ;Programm verwendet wird.
16 ;
17 BLK FORM 0.1 Z X+200 Y-50 Z-10
18 BLK FORM 0.2  X+300  Y+50  Z+30
19 ;
20 ;Werkzeugaufruf
21 TOOL CALL 4 Z S8000
22 ;
23 L  Z+100 R0 F9999 M3 ;Freifahren
24 ;
25 FN 0: Q30 =+12 ;WAHL DER TASCHENKONTUR
26 ;
27 ;Definition der Konturlabel
28 CYCL DEF 14.0 KONTUR
29 CYCL DEF 14.1 KONTURLABEL10 /2
30 ;
31 ;Bearbeitungszyklen
32 CYCL DEF 20 KONTUR-DATEN ~
    Q1=-34   ;FRAESTIEFE ~
    Q2=+1    ;BAHN-UEBERLAPPUNG ~
    Q3=+0    ;AUFMASS SEITE ~
    Q4=+0    ;AUFMASS TIEFE ~
    Q5=+30   ;KOOR. OBERFLAECHE ~
    Q6=+2    ;SICHERHEITS-ABST. ~
    Q7=+5    ;SICHERE HOEHE ~
    Q8=+0    ;RUNDUNGSRADIUS ~
    Q9=+1    ;DREHSINN
33 CYCL DEF 22 AUSRAEUMEN ~
    Q10=-4    ;ZUSTELL-TIEFE ~
    Q11=+300  ;VORSCHUB TIEFENZ. ~
    Q12=+1500 ;VORSCHUB RAEUMEN ~
    Q18=+0    ;VORRAEUM-WERKZEUG ~
    Q19=+500  ;VORSCHUB PENDELN ~
    Q208=+99999 ;VORSCHUB RUECKZUG ~
    Q401=+70   ;VORSCHUBFAKTOR ~
    Q404=+0    ;NACHRAEUMSTRATEGIE
34 CYCL CALL M3
35 L  Z+100 R0 F99999 ;Freifahren
36 M30 ;Programmende
37 ;
38 ;Unterprogramme
39 ;
40 LBL 2 ;Kontur Insel
41 L  X+200  Y+26 RL
42 L  X+300  Y+36
43 L  Y-36
44 L  X+200  Y-26
45 L  X+200  Y+26
46 LBL 0
47 ;
48 LBL 10 ;Unterprogramm Auswahl Tasche
49 CALL LBL Q30
50 LBL 0
51 ;
52 LBL 11 ;Kontur Tasche 1
53 L  X+194  Y-56 RR
54 L  Y+46
55 L  X+306
56 L  Y-46
57 L  X+194
58 LBL 0
59 ;
60 LBL 12 ;Kontur Tasche 2
61 L  X+194  Y-56 RR
62 L  Y+56
63 L  X+306
64 L  Y-56
65 L  X+194
66 LBL 0
67 END PGM 2145_DE MM