0 BEGIN PGM 2155_DE MM
1 ;NC-Programm, um eine Kontur mittels OCM-Zyklen zu Bearbeiten.
2 ;In diesem Beispielprogramm bearbeitet die Steuerung eine Kontur
3 ;in Form einer runden Nut. Die Nutkontur berechnet die Steuerung
4 ;im NC-Programm 21551_de.h. Die Abmasse die Kontur definieren Sie
5 ;in dem Konturprogramm.
6 ;Die Bearbeitung ist in vier Schritten definiert:
7 ;-Kontur ausraeumen
8 ;-Schlichten Taschentiefe
9 ;-Schlichten Taschenseite
10 ;-Entgraten Konturoberflaeche
11 ;
12 BLK FORM 0.1 Z X+0 Y+0 Z-20
13 BLK FORM 0.2  X+100  Y+100  Z+0
14 ;
15 ;Ausraeumen
16 ;Werkzeugaufruf
17 TOOL CALL "MILL_D8_ROUGH" Z S12000 F2000
18 L X+0 Y+0 R0 FMAX M3
19 ;Konturdefinition
20 CONTOUR DEF P1 = "21551_de.h"
21 CYCL DEF 271 OCM KONTURDATEN ~
 Q203=+0 ;KOOR. OBERFLAECHE ~
 Q201=-10 ;TIEFE ~
 Q368=+0.2 ;AUFMASS SEITE ~
 Q369=+0.1 ;AUFMASS TIEFE ~
 Q260=+100 ;SICHERE HOEHE ~
 Q578=+0.2 ;FAKTOR INNENECKEN ~
 Q569=+0 ;OFFENE BEGRENZUNG
22 ;Bearbeitungszyklus
23 CYCL DEF 272 OCM SCHRUPPEN ~
 Q202=+10 ;ZUSTELL-TIEFE ~
 Q370=+0.612 ;BAHN-UEBERLAPPUNG ~
 Q207=+5867 ;VORSCHUB FRAESEN ~
 Q568=+0.6 ;FAKTOR EINTAUCHEN ~
 Q253=MAX ;VORSCHUB VORPOS. ~
 Q200=+2 ;SICHERHEITS-ABST. ~
 Q438=-1 ;AUSRAEUM-WERKZEUG ~
 Q577=+0.2 ;FAKTOR ANFAHRRADIUS ~
 Q351=+1 ;FRAESART ~
 Q576=+18000 ;SPINDELDREHZAHL ~
 Q579=+1 ;FAKTOR S EINTAUCHEN ~
 Q575=+0 ;ZUSTELLSTRATEGIE
24 ;Zyklusaufruf
25 CYCL CALL
26 ;Freifahren
27 L Z+100 R0 FMAX M5
28 ;
29 ;Schlichten
30 ;Werkzeugaufruf
31 TOOL CALL "MILL_D6_FINISH" Z S18000 F1000
32 ;Bearbeitungszyklus
33 CYCL DEF 273 OCM SCHLICHTEN TIEFE ~
 Q370=+1 ;BAHN-UEBERLAPPUNG ~
 Q385=AUTO ;VORSCHUB SCHLICHTEN ~
 Q568=+0.3 ;FAKTOR EINTAUCHEN ~
 Q253=MAX ;VORSCHUB VORPOS. ~
 Q200=+2 ;SICHERHEITS-ABST. ~
 Q438=-1 ;AUSRAEUM-WERKZEUG ~
 Q595=+0 ;STRATEGIE ~
 Q577=+0.2 ;FAKTOR ANFAHRRADIUS
34 ;Zyklusaufruf
35 CYCL CALL M3
36 ;Bearbeitungszyklus
37 CYCL DEF 274 OCM SCHLICHTEN SEITE ~
 Q338=+0 ;ZUST. SCHLICHTEN ~
 Q385=AUTO ;VORSCHUB SCHLICHTEN ~
 Q253=MAX ;VORSCHUB VORPOS. ~
 Q200=+2 ;SICHERHEITS-ABST. ~
 Q14=+0 ;AUFMASS SEITE ~
 Q438=-1 ;AUSRAEUM-WERKZEUG ~
 Q351=+1 ;FRAESART
38 ;Zyklusaufruf
39 CYCL CALL
40 ;Freifahren
41 L Z+100 R0 FMAX M5
42 ;
43 ;Entgraten
44 ;Werkzeugaufruf
45 TOOL CALL "NC_DEBURRING_D6" Z S18000 F700
46 ;Bearbeitungszyklus
47 CYCL DEF 277 OCM ANFASEN ~
 Q353=-1 ;TIEFE WERKZEUGSPITZE ~
 Q359=+0.5 ;FASENBREITE ~
 Q207=AUTO ;VORSCHUB FRAESEN ~
 Q253=MAX ;VORSCHUB VORPOS. ~
 Q200=+2 ;SICHERHEITS-ABST. ~
 Q438=-1 ;AUSRAEUM-WERKZEUG ~
 Q351=+1 ;FRAESART ~
 Q354=+0 ;FASENWINKEL
48 ;Zyklusaufruf
49 CYCL CALL M3
50 ;
51 ;Freifahren
52 L Z+100 R0 FMAX
53 ;Programmmende
54 M30
55 END PGM 2155_DE MM