0  BEGIN PGM 4040_DE MM 
1  BLK FORM 0.1 Z X-100 Y-100 Z-100
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  ;Kreiszapfen fraesen
4  ;Werkzeugaufruf
5  TOOL CALL 10 Z S3000 F800
6  L  X+0  Y+0  Z+100 R0 FMAX M3
7  CYCL DEF 257 KREISZAPFEN ~
    Q223=+200  ;FERTIGTEIL-DURCHM. ~
    Q222=+283  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-80   ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG
8  M99
9  L  Z+100 R0 FMAX M5
10 ;Nuten auf Zylindermantel fraesen
11 ;Werkzeugaufruf
12 TOOL CALL 2 Z S5000 F500
13 ;Auf eine sichere Position  fahren um die A-Achse zu schwenken
14 L  X+0  Y+0 R0 FMAX M3
15 M140 MB MAX F5000
16 ;A-Achse schwenken
17 PLANE AXIAL  A-90 TURN FMAX
18 CALL LBL "Bearbeitung"
19 LBL "Takt"
20 ;Inkrementale Bewegung der C-Achse
21 PLANE AXIAL IC+10 TURN FMAX
22 CALL LBL "Bearbeitung"
23 ;Wiederholung des Taktes
24 CALL LBL "Takt" REP34
25 M140 MB MAX F5000
26 PLANE RESET TURN FMAX
27 M30 ;Programm Ende
28 ;Unterprogramm 
29 LBL "Bearbeitung"
30 ;Bearbeitungszyklus
31 ;Wichtig Koordinaten Oberflaeche = Radius vom Zylinder!!!
32 CYCL DEF 253 NUTENFRAESEN ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+20   ;NUTLAENGE ~
    Q219=+5    ;NUTBREITE ~
    Q368=+0    ;AUFMASS SEITE ~
    Q374=+100  ;DREHLAGE ~
    Q367=+0    ;NUTLAGE ~
    Q207=+500  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-5    ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+100  ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q366=+0    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
33 ;Position mit Zyklusaufruf
34 L  X+0  Y+25 R0 FMAX M99
35 LBL 0
36 END PGM 4040_DE MM