0  BEGIN PGM 4225_DE MM 
1  ;Programm, um mehrere Bearbeitungen, die auf
2  ;einer Geraden liegen, mit angestelltem
3  ;Werkzeug durchzufuehren.
4  ;In diesem Beispiel werden zunaechst mit einem
5  ;Fraeser Taschen gefraest, um eine Flaeche zu
6  ;erzeugen. In einem zweiten Arbeitsgang
7  ;werden rechtwinklig zur Grundflaeche der
8  ;Tasche, Bohrungen erstellt.
9  ;Zunaechst muessen Sie alle notwendigen
10 ;Parameter definieren. Auch die Werkzeugdaten
11 ;und gegebenenfalls die Zyklen muessen Sie
12 ;anpassen.
13 ;!WICHTIG! Das Programm ist fuer Maschinen
14 ;erstellt, die fuer ein Schwenken der
15 ;Bearbeitungsebene mit Raumwinkel eingestellt
16 ;sind. Wenn Ihre Maschine nur mit
17 ;Achswinkeln arbeitet, muessen Sie auch die
18 ;Eingaben im Zyklus 19 aendern. Auch muessen
19 ;sie vor dem Schwenken der Beabeitungsebene
20 ;auf eine, maschinenabhaengige,
21 ;sichere Position fahren,
22 ;damit es beim Fahren der Rundachsen nicht
23 ;zu einer Kollision kommt.
24 ;
25 BLK FORM 0.1 Z X+0 Y+0 Z-30
26 BLK FORM 0.2  X+100  Y+100  Z+0
27 ;
28 ;Parametereingabe
29 ;Position und Lage der Bohrungen
30 FN 0: Q10 =+15 ;KOORDINATE 1.BOHRUNG IN X
31 FN 0: Q11 =+15 ;KOORDINATE 1.BOHRUNG IN Y
32 FN 0: Q12 =+10 ;ABSTAND DER BOHRUNGEN IN DER
33 ;              ;X-ACHSE
34 FN 0: Q13 =+10 ;ABSTAND DER BOHRUNGEN IN DER
35 ;              ;Y-ACHSE
36 FN 0: Q14 =+8 ;ANZAHL DER BOHRUNGEN
37 FN 0: Q15 =+30 ;RAUMWINKEL A DER BEARBEITUNG
38 FN 0: Q16 =+0 ;RAUMWINKEL B DER BEARBEITUNG
39 FN 0: Q17 =-150 ;RAUMWINKEL C DER BEARBEITUNG
40 ;Parameter fuer das Fraesn der Tasche
41 FN 0: Q2 =+3 ;TIEFE DER TASCHE
42 FN 0: Q3 =+8 ;DURCHMESSER DER TASCHE
43 FN 0: Q18 =+400 ;VORSCHUB TASCHE FRAESEN
44 ;Parameter fuer das Bohren
45 FN 0: Q4 =+20 ;TIEFE BOHRUNG
46 FN 0: Q19 =+500 ;VORSCHUB BOHREN
47 ;Parametereingabe Ende
48 ;
49 ;Berechnungen
50 FN 2: Q1 =+Q14 - +2 ;Anzahl der Wiederholungen
51 ;Berechnungen Ende
52 ;
53 M3
54 ;Werkzeugaufruf Schaftfraeser fuer Zentrierung
55 TOOL CALL 4 Z S2000 F300
56 ;Aufruf Unterprogramm fuer Reset
57 CALL LBL 10
58 ;Zyklus zum Erstellen einer Planflaeche /
59 ;Zentrierung
60 CYCL DEF 252 KREISTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+Q3   ;KREISDURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207=+Q18  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-Q2   ;TIEFE ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+Q18  ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
61 ;Aufruf Unterprogramm zur Positionierung und
62 ;Bearbeitung
63 CALL LBL 3
64 ;Freifahren
65 L  Z+50 F2222
66 ;
67 ;Werkzeugaufruf Bohrer
68 TOOL CALL 227 Z S1000 F300
69 ;Definition Bohrzyklus
70 CYCL DEF 200 BOHREN ~
    Q200=+5    ;SICHERHEITS-ABST. ~
    Q201=-Q4   ;TIEFE ~
    Q206=+Q19  ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q395=+0    ;BEZUG TIEFE
71 ;Aufruf Unterprogramm zur Positionierung und
72 ;Bearbeitung
73 CALL LBL 3
74 ;Freifahren und Programmende
75 L  Z+50 F2222 M30
76 ;
77 ;Unterprogramm zur Positionierung und
78 ;Bearbeitung
79 LBL 3
80 ;Nullpunktverschiebung auf die erste
81 ;Bearbeitung
82 CYCL DEF 7.0 NULLPUNKT
83 CYCL DEF 7.1  Y+Q10
84 CYCL DEF 7.2  X+Q11
85 ;Schwenken der Bearbeitungsebene
86 CYCL DEF 19.0 BEARBEITUNGSEBENE
87 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
88 ;Sichere Position anfahren
89 M140 MB MAX F9999
90 ;Positionieren der Rundachsen
91 L  A+Q120  B+Q121  C+Q122 R0 FMAX
92 ;Anfahren der ersten Bearbeitungsposition
93 L  X+0  Y+0  Z+50 R0 FMAX M3
94 ;Zyklusaufruf
95 M99
96 ;Programmteilwiederholung fuer die weiteren
97 ;Bearbeitungen
98 LBL 2
99 ;Aufruf Unterprogramm fuer weitere
100 ;Bearbeitungen
101 CALL LBL 1
102 ;Aufruf der Wiederholungen
103 CALL LBL 2 REPQ1
104 ;Freifahren
105 M140 MB MAX F9999
106 ;Aufruf Unterprogramm fuer Reset
107 CALL LBL 10
108 ;Zurueckschwenken der Rundachsen
109 L  A+Q120  B+Q121  C+Q122 R0 FMAX
110 ;Reset der Nullpunktverschiebung
111 CYCL DEF 7.0 NULLPUNKT
112 CYCL DEF 7.1  Y+0
113 CYCL DEF 7.2  X+0
114 LBL 0
115 ;
116 ;Unterprogramm fuer weitere Bearbeitungen
117 LBL 1
118 ;Aufruf Unterprogramm fuer Reset
119 CALL LBL 10
120 ;Nullpunktverschiebung inkremental auf die
121 ;naechste Position
122 CYCL DEF 7.0 NULLPUNKT
123 CYCL DEF 7.1 IX+Q12
124 CYCL DEF 7.2 IY+Q13
125 ;Bearbeitungsebene schwenken
126 CYCL DEF 19.0 BEARBEITUNGSEBENE
127 CYCL DEF 19.1  A+Q15  B+Q16  C+Q17
128 ;Bearbeitungsposition anfahren
129 L  X+0  Y+0  Z+50 R0 FMAX
130 ;Zyklusaufruf
131 M99
132 ;Aufruf Unterprogramm fuer Reset
133 CALL LBL 10
134 LBL 0
135 ;
136 ;Unterprogramm fuer Reset
137 LBL 10
138 ;Bearbeitungsebene zurueckschwenken
139 CYCL DEF 19.0 BEARBEITUNGSEBENE
140 CYCL DEF 19.1  A+0  B+0  C+0
141 ;Bearbeitungsebene schwenken abwaehlen
142 CYCL DEF 19.0 BEARBEITUNGSEBENE
143 CYCL DEF 19.1
144 ;Reset Massfaktor
145 CYCL DEF 11.0 MASSFAKTOR
146 CYCL DEF 11.1 SCL 1
147 ;Reset Rotation
148 CYCL DEF 10.0 DREHUNG
149 CYCL DEF 10.1  ROT+0
150 LBL 0
151 END PGM 4225_DE MM