0  BEGIN PGM 42301_DE MM 
1  ;NC-Programm zur Berechnung und Bearbeitung
2  ;der Foerderschraube.
3  ;Ausserdem ist im Programmteil "SUBLOOP" die
4  ;Kontur in der Ebene X/Y programmiert. Da es
5  ;in diesem Fall um eine Kontur handelt die
6  ;aus drei gleichen Abschnitten besteht, hat
7  ;man diese einmal programmiert und dann zwei
8  ;mal um je 120 Grad rotiert wiederholt.
9  ;
10 ;Um die Hinterschnitte an dem Werkstueck
11 ;fertigen zu koennen, ist es noetig das
12 ;Werkzeug anzustellen.
13 ;Hierzu nutzt man die Funktion TCPM, hierbei
14 ;bleibt das Koordinatensystem
15 ;unveraendert. Aber beim Verfahren der
16 ;Rundachsen beruecksichtigt die Steuerung
17 ;die Kinematik und fuehrt den Tool Center
18 ;Point, in diesem Fall das Zentrum des
19 ;Kugelfraesers, auf der programmierten
20 ;Bahn.
21 ;Die Ausgleichsbewegungen der C-Achse, die bei
22 ;den Kreisbahnen der Kontur in diesem Programm
23 ;programmiert sind, sind so gewaehlt,
24 ;dass keine Konturverletzungen entstehen.
25 ;
26 ;Programmbeginn
27 Q10 = Q9 ;aktuelle Tiefe
28 Q12 = Q2 / Q1 ;Rotation je Millimeter Tiefe
29 Q20 = 5 + Q108 + Q7 ;Erster Radius inklusive Werkzeugradius und Aufmass
30 Q30 = Q6 - ( ( Q6 - ( 25 + Q20 ) ) / 2 ) ;Kreismittelpunkt fuer ein weiches Anfahren
31 PLANE RESET STAY ;Schwenken zuruecksetzen
32 L  Z+Q5 R0 FMAX M3 ;Sichere Hoehe anfahren
33 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL AXIS ;Funktion TCPM aktivieren
34 CC  X+0  Y+0 ;Kreismittelpunkt fuer das Vorpositionieren
35 LP  PR+Q6  PA+0 R0 FMAX ;Vorpositionieren
36 L  B+Q4  A+0  C+0 R0 FMAX ;Anstellwinkel der B-Achse anfahren
37 ;
38 ;Sprungmarke fuer Wiederholung
39 LBL "MAINLOOP"
40 Q11 = Q10 * Q12 ;Aktuelle Rotation berechnen
41 ;
42 ;Koordinatensystem drehen
43 CYCL DEF 10.0 DREHUNG
44 CYCL DEF 10.1  ROT+Q11
45 ;
46 L  C+Q11 R0 FMAX ;Ausgleichsbewegung der C-Achse
47 L  Z+Q10 R0 FMAX ;Neue Z-Koordinate anfahren
48 CC  X+0  Y+0 ;Mittelpunkt fuer Vorpositionierung
49 LP  PR+Q6  PA+0 R0 FMAX ;Auf sicheren Radius vorpositionieren
50 CC  X+Q30  Y+0 ;Kreismittelpunkt fuer die Anfahrbewegung
51 CP  PA+180 DR- F AUTO ;Anfahrbewegung
52 CC  X+25  Y+0 ;Kreismittelpunkt Radius 5
53 ;
54 ;Programmteilwiederholung
55 ;in der die Kontur beschrieben ist
56 LBL "SUBLOOP"
57 CP  PA+123.5 IC+33.5 DR+
58 CC  X+15.82  Y+13.86
59 CP IPA-102.6 IC+29.3 DR-
60 CC  X-23.05  Y-1.02
61 CP IPA+44.1 IC+48.8 DR+
62 CYCL DEF 10.0 DREHUNG
63 CYCL DEF 10.1 IROT+120
64 CC  X+25  Y+0
65 CP  PA+0 IC+8.4 DR+
66 CALL LBL "SUBLOOP" REP2
67 ;
68 CC  X+Q30  Y+0 ;Kreismittelpunkt fuer Abfahrbewegung
69 CP  PA+0 DR- F AUTO ;Auf sichere Position fahren
70 L  Z+Q5 R0 FMAX ;Auf sichere Hoehe fahren
71 LBL 0
72 ;
73 Q10 = Q10 + Q3 ;Neue Z-Koordinate berechnen
74 FN 11: IF +Q10 GT +Q1 GOTO LBL "MAINLOOP" ;Vergleich ob Tiefe erreicht und gegebenefalls Sprung
75 FN 0: Q10 =+Q1 ;Y-Koordinate gleich Tiefe
76 ;Sprung zum Konturfraesen
77 CALL LBL "MAINLOOP"
78 L  B+0  C+0  A+0 R0 FMAX M5 ;Alle Rundachsen zurueckschwenken
79 FUNCTION RESET TCPM ;Funktion TCPM zuruecksetzen
80 ;Programmende
81 END PGM 42301_DE MM