0  BEGIN PGM 4240_de MM 
1  ;NC-Programm um mit einer Spannpyramide vier 
2  ;Werkstuecke zu bearbeiten.
3  ;An jedes der Werkstuecke, mit dem Abmessungen
4  ;60*60*60mm, fraest die Steuerung eine Fase
5  ;von 5*45 Grad. Die Bearbeitung erfolgt mit
6  ;einem eingeschwenkten Schaftfraeser.
7  ;
8  ;Die Werkstuecke sind einer Spannpyramide
9  ;mit einem Winkel von 45 Grad gespannt.
10 ;
11 ;Die Werkstuecke sind wie folgt angeordnet:
12 ;Werkstueck 1 -> PRESET 6 --> Vorne
13 ;Werkstueck 2 -> PRESET 7 --> Rechts
14 ;Werkstueck 3 -> PRESET 8 --> Hinten
15 ;Werkstueck 4 -> PRESET 9 --> Links
16 ;
17 ;Die Bearbeitung des Werkstuecks ist im
18 ;Unterprogramm "BEARBEITUNG" programmiert.
19 ;Dieses Unterprogramm arbeitet die Steuerung
20 ;an jedem Preset, mit geaendertem Winkel
21 ;fuer die Ausrichtung, ab.
22 ;Wichtig ist, dass die Winkel fuer die
23 ;Ausrichtung der Spannpyramide jeweils in
24 ;den Parametern QR170, QR171 und QR172
25 ;hinterlegt sind.
26 ;Im Unterprogramm "BEARBEITUNG" ist zunaechst
27 ;das Werkzeug definiert. Anschliessend ruft 
28 ;die Steuerung fuer jede zu fraesende Flaeche
29 ;ein LBL "TILT..." und das LBL "MILL" auf.
30 ;In den Unterprogrammen "TILT..." ist die
31 ;Nullpunktverschiebung und das
32 ;Einschwenken der Bearbeitungsebene fuer die
33 ;jeweilige Bearbeitung, bezogen auf das
34 ;Werkstueckkoordinatensystem, definiert.
35 ;Danach ruft die Steuerung das LBL "TILT_NEW".
36 ;In diesem Unterprogramm errechnet die
37 ;Steuerung dann aus den Winkeln fuer das
38 ;Ausrichten der Spannposition, der Nullpunkt-
39 ;verschiebung und dem Einschwenken der
40 ;Bearbeitungsebene den resultierenden
41 ;Raumwinkel und die Nullpunktverschiebung 
42 ;und aktiviert diese. Danach erfolgt die
43 ;Bearbeitung, die im LBL "MILL" programmiert
44 ;ist.
45 ;
46 * -Definition der Seite 1 VORNE
47 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+6    ;BEZUGSPUNKT-NUMMER
48 ;SPA ausgerichtet = QR170
49 QR170 = 45
50 ;SPB ausgerichtet = QR171
51 QR171 = 0
52 ;SPC ausgerichtet = QR172
53 QR172 = 0
54 CALL LBL "BEARBEITUNG"
55 ;
56 * -Definition der Seite 2 RECHTS
57 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+7    ;BEZUGSPUNKT-NUMMER
58 ;SPA ausgerichtet = QR170
59 QR170 = 45
60 ;SPB ausgerichtet = QR171
61 QR171 = 0
62 ;SPC ausgerichtet = QR172
63 QR172 = 90
64 CALL LBL "BEARBEITUNG"
65 ;
66 * -Definition Seite 3 HINTEN
67 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+8    ;BEZUGSPUNKT-NUMMER
68 ;SPA ausgerichtet = QR170
69 QR170 = 45
70 ;SPB ausgerichtet = QR171
71 QR171 = 0
72 ;SPC ausgerichtet = QR172
73 QR172 = 180
74 CALL LBL "BEARBEITUNG"
75 ;
76 * -Definition Seite 4 LINKS
77 CYCL DEF 247 BEZUGSPUNKT SETZEN ~
    Q339=+9    ;BEZUGSPUNKT-NUMMER
78 ;SPA ausgerichtet = QR170
79 QR170 = 45
80 ;SPB ausgerichtet = QR171
81 QR171 = 0
82 ;SPC ausgerichtet = QR172
83 QR172 = 270
84 CALL LBL "BEARBEITUNG"
85 ;
86 ;Alle Koordinatenumrechnungen zuruecksetzen
87 CALL LBL "RESET"
88 ;
89 ;Programm Ende
90 M30
91 ;
92 ;Unterprogramme
93 * - BEARBEITUNG
94 LBL "BEARBEITUNG"
95 * - Flaeche fraesen 45
96 TOOL CALL "D16" Z S9000 F2000
97 CALL LBL "SAFE"
98 CALL LBL "TILT1"
99 CALL LBL "MILL"
100 CALL LBL "TILT2"
101 CALL LBL "MILL"
102 CALL LBL "TILT3"
103 CALL LBL "MILL"
104 CALL LBL "TILT4"
105 CALL LBL "MILL"
106 LBL 0
107 ;
108 * - Fraesen
109 LBL "MILL"
110 L  X-20  Y+5  Z+50 R0 FMAX
111 L  Z+5 R0 FMAX
112 L  Z+0 R0 F2000
113 APPR LT  X+0  Y-1 LEN10 RL F AUTO
114 L  X+60
115 DEP LT LEN10
116 L  Z+50 R0 FMAX
117 LBL 0
118 ;
119 * - Schwenken 0 Grad
120 LBL "TILT0"
121 PLANE RESET STAY
122 CYCL DEF 7.0 NULLPUNKT
123 CYCL DEF 7.1  X+0
124 CYCL DEF 7.2  Y+0
125 CYCL DEF 7.3  Z+0
126 CALL LBL "SAFE"
127 PLANE SPATIAL SPA+0 SPB+0 SPC+0 STAY SEQ-
128 ;Umrechnen auf Ebene
129 CALL LBL "TILT_NEW"
130 LBL 0
131 ;
132 * - Schwenken 1
133 LBL "TILT1"
134 PLANE RESET STAY
135 CYCL DEF 7.0 NULLPUNKT
136 CYCL DEF 7.1  X-30
137 CYCL DEF 7.2  Y-30
138 CYCL DEF 7.3  Z-5
139 CALL LBL "SAFE"
140 PLANE SPATIAL SPA+45 SPB+0 SPC+0 STAY SEQ-
141 ;Umrechnen auf Ebene
142 CALL LBL "TILT_NEW"
143 LBL 0
144 ;
145 * - Schwenken 2
146 LBL "TILT2"
147 PLANE RESET STAY
148 CYCL DEF 7.0 NULLPUNKT
149 CYCL DEF 7.1  X+30
150 CYCL DEF 7.2  Y-30
151 CYCL DEF 7.3  Z-5
152 CALL LBL "SAFE"
153 PLANE SPATIAL SPA+45 SPB+0 SPC+90 STAY SEQ-
154 ;Umrechnen auf Ebene
155 CALL LBL "TILT_NEW"
156 LBL 0
157 ;
158 * - Schwenken 3
159 LBL "TILT3"
160 PLANE RESET STAY
161 CYCL DEF 7.0 NULLPUNKT
162 CYCL DEF 7.1  X+30
163 CYCL DEF 7.2  Y+30
164 CYCL DEF 7.3  Z-5
165 CALL LBL "SAFE"
166 PLANE SPATIAL SPA+45 SPB+0 SPC+180 STAY SEQ-
167 ;Umrechnen auf Ebene
168 CALL LBL "TILT_NEW"
169 LBL 0
170 ;
171 * - Schwenken 4
172 LBL "TILT4"
173 PLANE RESET STAY
174 CYCL DEF 7.0 NULLPUNKT
175 CYCL DEF 7.1  X-30
176 CYCL DEF 7.2  Y+30
177 CYCL DEF 7.3  Z-5
178 CALL LBL "SAFE"
179 PLANE SPATIAL SPA+45 SPB+0 SPC+270 STAY SEQ-
180 ;Umrechnen auf Ebene
181 CALL LBL "TILT_NEW"
182 LBL 0
183 ;
184 * - Sichere Position
185 LBL "SAFE"
186 M3
187 L  Z+300 R0 FMAX M91
188 L  X+400  Y-300 R0 FMAX M91
189 LBL 0
190 ;
191 * - Ruecksetzen aller Koordinatenumrechnungen
192 LBL "RESET"
193 CALL LBL "SAFE"
194 PLANE RESET TURN FMAX
195 CYCL DEF 7.0 NULLPUNKT
196 CYCL DEF 7.1  X+0
197 CYCL DEF 7.2  Y+0
198 CYCL DEF 7.3  Z+0
199 CYCL DEF 8.0 SPIEGELUNG
200 CYCL DEF 8.1
201 CYCL DEF 10.0 DREHUNG
202 CYCL DEF 10.1  ROT+0
203 CYCL DEF 11.0 MASSFAKTOR
204 CYCL DEF 11.1 SCL 1
205 LBL 0
206 ;
207 * - Umrechnung der Winkel
208 LBL "TILT_NEW"
209 ;Auslesen 3D-ROT
210 FN 18: SYSREAD Q170 = ID210 NR5 IDX1 ;3D-ROT SPA
211 FN 18: SYSREAD Q171 = ID210 NR5 IDX2 ;3D-ROT SPB
212 FN 18: SYSREAD Q172 = ID210 NR5 IDX3 ;3D-ROT SPC
213 PLANE RESET STAY
214 ;Auslesen Nullpunktverschiebung
215 FN 18: SYSREAD Q175 = ID220 NR2 IDX1 ;NPV X
216 FN 18: SYSREAD Q176 = ID220 NR2 IDX2 ;NPV Y
217 FN 18: SYSREAD Q177 = ID220 NR2 IDX3 ;NPV Z
218 ;Ausrichtung einschwenken
219 CYCL DEF 7.0 NULLPUNKT
220 CYCL DEF 7.1  X+0
221 CYCL DEF 7.2  Y+0
222 CYCL DEF 7.3  Z+0
223 PLANE SPATIAL SPA+QR170 SPB+QR171 SPC+QR172 STAY
224 ;Nullpunktverschiebung auf ausgerichteter Flaeche
225 CYCL DEF 7.0 NULLPUNKT
226 CYCL DEF 7.1 IX+Q175
227 CYCL DEF 7.2 IY+Q176
228 CYCL DEF 7.3 IZ+Q177
229 ;ausgelesenen 3D-ROT draufschwenken
230 PLANE RELATIV SPC+Q172 STAY
231 PLANE RELATIV SPB+Q171 STAY
232 CALL LBL "SAFE"
233 PLANE RELATIV SPA+Q170 TURN FMAX SEQ-
234 LBL 0
235 END PGM 4240_de MM