0  BEGIN PGM 50051_DE MM 
1  ;Programm, um einen Kreiszapfen zu
2  ;bearbeiten, und anschliessend die
3  ;Oberflaeche schraeg abzufraesen.
4  ;
5  ;Werkzeugaufruf
6  TOOL CALL 15 Z S4000 F300
7  ;
8  L  Z+100 R0 FMAX M3 ;Auf sichere Hoehe fahren
9  L  X+Q7  Y+Q8 R0 FMAX ;Vorpositionieren
10 FN 3: Q80 =+Q1 * +2 ;Berechnung Durchmesser
11 ;Definition Kreiszapfen
12 CYCL DEF 257 KREISZAPFEN ~
    Q223=+Q80  ;FERTIGTEIL-DURCHM. ~
    Q222=+141  ;ROHTEIL-DURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207=+600  ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-50   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q376=+0    ;STARTWINKEL
13 M99
14 L  X+Q7  Y+Q8  Z+100 R0 FMAX
15 ;Nullpunkt in die  Mitte des Zapfens
16 ;schieben. Z Verschiebung auf die
17 ;Position, um die die Bearbeitungsebene
18 ;geschwenkt wird.
19 CYCL DEF 7.0 NULLPUNKT
20 CYCL DEF 7.1  Z+Q9
21 CYCL DEF 7.2  X+Q7
22 CYCL DEF 7.3  Y+Q8
23 ;Bearbeitungsebene schwenken
24 CYCL DEF 19.0 BEARBEITUNGSEBENE
25 CYCL DEF 19.1  A+Q11  B+0  C+0
26 ;Rundachsen auf Position fahren
27 L  A+Q120  B+Q121  C+Q122 R0 FMAX
28 ;Zyklus zur Planflaechenbearbeitung
29 ;definieren
30 CYCL DEF 232 PLANFRAESEN ~
    Q389=+2    ;STRATEGIE ~
    Q225=-Q1   ;STARTPUNKT 1. ACHSE ~
    Q226=-60   ;STARTPUNKT 2. ACHSE ~
    Q227=+40   ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+Q80  ;1. SEITEN-LAENGE ~
    Q219=+120  ;2. SEITEN-LAENGE ~
    Q202=+5    ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207=+600  ;VORSCHUB FRAESEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
31 M99
32 M140 MB MAX F9999 ;Freifahren
33 ;Bearbeitungsebene Schwenken aufheben
34 CYCL DEF 19.0 BEARBEITUNGSEBENE
35 CYCL DEF 19.1  A+0  B+0  C+0
36 CYCL DEF 19.0 BEARBEITUNGSEBENE
37 CYCL DEF 19.1
38 ;Rundachsen auf Null zuruecksetzen
39 L  A+Q120  B+Q121  C+Q122 R0 FMAX
40 ;Nullpunktverschiebung aufheben
41 CYCL DEF 7.0 NULLPUNKT
42 CYCL DEF 7.1  X+0
43 CYCL DEF 7.2  Y+0
44 CYCL DEF 7.3  Z+0
45 END PGM 50051_DE MM