0  BEGIN PGM 5080-DE MM 
1  ;In diesem Programm werden ein Rechteckzapfen
2  ;und eine Rechtecktasche, so wie ein
3  ;Kreiszapfen und eine Kreistasche bearbeitet
4  ;und anschliessend fraest man mit einem
5  ;angestelletm Werkzeug umlaufend eine Fase
6  ;an die Konturen. Das Bearbeiten der Konturen
7  ;ist im Hauptprogramm programmiert, für die
8  ;Fasen ruft man je ein weiteres Programm auf,
9  ;in welchem Sie die entsprechenden Parameter
10 ;eingeben müssen.
11 ;
12 BLK FORM 0.1 Z X+0 Y+0 Z-20
13 BLK FORM 0.2  X+200  Y+100  Z+2
14 ;Werkzeugaufruf
15 TOOL CALL 12 Z S6121 F4591
16 TOOL DEF 8
17 CYCL DEF 232 PLANFRAESEN ~
    Q389=+2    ;STRATEGIE ~
    Q225=+0    ;STARTPUNKT 1. ACHSE ~
    Q226=+0    ;STARTPUNKT 2. ACHSE ~
    Q227=+2    ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+200  ;1. SEITEN-LAENGE ~
    Q219=+100  ;2. SEITEN-LAENGE ~
    Q202=+5    ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
18 CYCL CALL M3
19 ;
20 ;Werkzeugaufruf
21 TOOL CALL 8 Z S9549 F2578
22 ;Aussenkontur mit SL-Zyklus fräsen 
23 CYCL DEF 14.0 KONTUR
24 CYCL DEF 14.1 KONTURLABEL1 /2 /3
25 CYCL DEF 20 KONTUR-DATEN ~
    Q1=-15   ;FRAESTIEFE ~
    Q2=+1    ;BAHN-UEBERLAPPUNG ~
    Q3=+0    ;AUFMASS SEITE ~
    Q4=+0    ;AUFMASS TIEFE ~
    Q5=+0    ;KOOR. OBERFLAECHE ~
    Q6=+2    ;SICHERHEITS-ABST. ~
    Q7=+50   ;SICHERE HOEHE ~
    Q8=+0    ;RUNDUNGSRADIUS ~
    Q9=+1    ;DREHSINN
26 CYCL DEF 22 AUSRAEUMEN ~
    Q10=-7.5  ;ZUSTELL-TIEFE ~
    Q11= AUTO ;VORSCHUB TIEFENZ. ~
    Q12= AUTO ;VORSCHUB RAEUMEN ~
    Q18=+0    ;VORRAEUM-WERKZEUG ~
    Q19=+2063 ;VORSCHUB PENDELN ~
    Q208=+99999 ;VORSCHUB RUECKZUG
27 CYCL CALL M3
28 ;
29 ;Taschen fräsen
30 CYCL DEF 251 RECHTECKTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+50   ;1. SEITEN-LAENGE ~
    Q219=+40   ;2. SEITEN-LAENGE ~
    Q220=+10   ;ECKENRADIUS ~
    Q368=+0    ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+0    ;TASCHENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-15   ;TIEFE ~
    Q202=+8    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+2063 ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
31 L  X+150  Y+50 R0 FMAX M3 M99
32 ;
33 CYCL DEF 252 KREISTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q223=+50   ;KREISDURCHMESSER ~
    Q368=+0    ;AUFMASS SEITE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-15   ;TIEFE ~
    Q202=+8    ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206=+2063 ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
34 L  X+50  Y+50 R0 FMAX M3 M99
35 ;
36 TOOL CALL 8 Z S9549 F2500
37 M3
38 ;Nullpunktverschiebung auf Mitte Kreis 
39 CYCL DEF 7.0 NULLPUNKT
40 CYCL DEF 7.1  X+50
41 CYCL DEF 7.2  Y+50
42 ;Aufruf Programm Fasen Kreis
43 CALL PGM 50801-de.h
44 ;Nullpunktverschiebung auf Mitte Rechteck
45 CYCL DEF 7.0 NULLPUNKT
46 CYCL DEF 7.1  X+150
47 CYCL DEF 7.2  Y+50
48 ;Aufruf Programm Fase Rechteck
49 CALL PGM 50802-de.h
50 CYCL DEF 7.0 NULLPUNKT
51 CYCL DEF 7.1  X+0
52 CYCL DEF 7.2  Y+0
53 CYCL DEF 7.3  Z+0
54 ;
55 M30 ;Programmende
56 ;Unterprogramme
57 ;Aussenkontur
58 LBL 1
59 L  X-20  Y-20 RL
60 L  X+220
61 L  Y+120
62 L  X-20
63 L  Y-20
64 LBL 0
65 ;Kontur Kreiszapfen
66 LBL 2
67 CC  X+50  Y+50
68 LP  PR+35  PA+0 RL
69 CP IPA-360 DR-
70 LBL 0
71 ;Kontur Rechteckzapfen
72 LBL 3
73 CC  X+150  Y+50
74 LP  PR+35  PA+0 RL
75 L  Y+20
76 RND R15
77 L IX-70
78 RND R15
79 L  Y+80
80 RND R15
81 L IX+70
82 RND R15
83 L  Y+50
84 LBL 0
85 END PGM 5080-DE MM