0  BEGIN PGM 5090-DE MM 
1  ;In diesem Programm werden, auf einer
2  ;geschwenkten Ebene, ein Rechteckzapfen
3  ;und eine Rechtecktasche bearbeitet
4  ;und anschliessend fraest man mit einem
5  ;angestellten Werkzeug umlaufend eine Fase
6  ;an die Konturen. Die Konturen programmieren Sie
7  ;mit Zyklen. Für die Fasen müssen Sie die
8  ;die Parameter definieren, aus denen die
9  ;Steuerung die Werkzeugbahnen berechnet.
10 ;
11 BLK FORM 0.1 Z X-50 Y-50 Z-40
12 BLK FORM 0.2  X+50  Y+50  Z+10
13 TOOL CALL 8 Z S12000 F5000 ;Fraeser D16
14 * - Reset
15 M129
16 CYCL DEF 7.0 NULLPUNKT
17 CYCL DEF 7.1  X+0
18 CYCL DEF 7.2  Y+0
19 CYCL DEF 7.3  Z+0
20 PLANE RESET STAY
21 M3
22 * - Bearbeitungsebene einschwenken
23 PLANE SPATIAL SPA+15 SPB+0 SPC+0 TURN MB100 FMAX
24 CYCL DEF 232 PLANFRAESEN ~
    Q389=+2    ;STRATEGIE ~
    Q225=-50   ;STARTPUNKT 1. ACHSE ~
    Q226=-60   ;STARTPUNKT 2. ACHSE ~
    Q227=+20   ;STARTPUNKT 3. ACHSE ~
    Q386=+0    ;ENDPUNKT 3. ACHSE ~
    Q218=+100  ;1. SEITEN-LAENGE ~
    Q219=+120  ;2. SEITEN-LAENGE ~
    Q202=+20   ;MAX. ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q370=+1    ;MAX. UEBERLAPPUNG ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q385= AUTO ;VORSCHUB SCHLICHTEN ~
    Q253= MAX ;VORSCHUB VORPOS. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q357=+2    ;SI.-ABSTAND SEITE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
25 L  X+0  Y+0  Z+100 R0 FMAX M3 M99
26 CYCL DEF 251 RECHTECKTASCHE ~
    Q215=+0    ;BEARBEITUNGS-UMFANG ~
    Q218=+60   ;1. SEITEN-LAENGE ~
    Q219=+50   ;2. SEITEN-LAENGE ~
    Q220=+10   ;ECKENRADIUS ~
    Q368=+0    ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+0    ;TASCHENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-10   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q369=+0    ;AUFMASS TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q338=+0    ;ZUST. SCHLICHTEN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q366=+1    ;EINTAUCHEN ~
    Q385=+500  ;VORSCHUB SCHLICHTEN
27 L  X+0  Y+0 R0 FMAX M3 M99
28 CYCL DEF 256 RECHTECKZAPFEN ~
    Q218=+80   ;1. SEITEN-LAENGE ~
    Q424=+100  ;ROHTEILMASS 1 ~
    Q219=+65   ;2. SEITEN-LAENGE ~
    Q425=+120  ;ROHTEILMASS 2 ~
    Q220=+10   ;ECKENRADIUS ~
    Q368=+0    ;AUFMASS SEITE ~
    Q224=+0    ;DREHLAGE ~
    Q367=+0    ;ZAPFENLAGE ~
    Q207= AUTO ;VORSCHUB FRAESEN ~
    Q351=+1    ;FRAESART ~
    Q201=-10   ;TIEFE ~
    Q202=+10   ;ZUSTELL-TIEFE ~
    Q206=+3000 ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q370=+1    ;BAHN-UEBERLAPPUNG ~
    Q437=+0    ;ANFAHRPOSITION
29 L  X+0  Y+0 R0 FMAX M3 M99
30 ;
31 * - Fase Parameter
32 Q1 = 2 ;FASENLAENGE
33 Q2 = 30 ;FASENWINKEL
34 Q13 = 60 ;LAENGE X
35 Q3 = 50 ;BREITE Y
36 Q5 = 10 ;RADIUS
37 Q4 = 1 ;BEARBEITUNG 1=INNEN 2=AUSSEN
38 TOOL CALL  DL-0.5 ;Ueberlauf um saubere Fasenunterkante zu bekommen
39 CALL LBL "fase"
40 ;
41 * - Fase Parameter
42 Q1 = 2 ;FASENLAENGE
43 Q2 = 30 ;FASENWINKEL
44 Q13 = 80 ;LAENGE X
45 Q3 = 65 ;BREITE Y
46 Q5 = 10 ;RADIUS
47 Q4 = 2 ;BEARBEITUNG 1=INNEN 2=AUSSEN
48 TOOL CALL  DL-0.5 ;Ueberlauf um saubere Fasenunterkante zu bekommen
49 CALL LBL "fase"
50 ;
51 FUNCTION RESET TCPM
52 * - auf sichere Position fahren
53 L  Z+500 R0 FMAX M91
54 L  X+800  Y+600 R0 FMAX M91
55 * - Bearbeitungsebene zurueckschwenken
56 PLANE RESET TURN FMAX
57 * - Programmende
58 M30
59 * - Unterprogramme
60 LBL "fase"
61 ;Abfrage aussen oder innen
62 FN 9: IF +Q4 EQU +1 GOTO LBL "innen"
63 FN 9: IF +Q4 EQU +2 GOTO LBL "aussen"
64 STOP
65 ;Bitte Q4 waehlen aussen oder innen
66 ;
67 LBL "innen"
68 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
69 FN 11: IF +Q5 GT +0 GOTO LBL "radius"
70 Q5 = Q108
71 LBL "radius"
72 Q10 = Q108 * ( COS Q2 ) ;Berechne WZR-Korrektur Radius
73 Q11 = ( Q3 / 2 ) - Q10 ;Breite Y - WZR-Korrektur Radius
74 QL11 = Q5 - Q10
75 Q21 = ( Q3 / 2 ) - Q5 ;Mitte CC Y
76 Q31 = ( Q13 / 2 ) - Q5 ;Mitte CC X
77 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;WZR-Korrektur Z
78 QL13 = Q11 - Q108 ;Anfahrposition Y
79 QL12 = Q12 - 2 ;Anfahrposition Z
80 L  X-Q108  Y-QL13  Z+50 R0 FMAX
81 L  A+Q2  B+0  C+0 R0 FMAX ;Wichtig alle drei Rundachsen wegen TCPM ... AXIS SPAT
82 L  Z-QL12 R0 F AUTO
83 CC  X+0  Y-QL13
84 CP  PA-90  Z-Q12 DR+
85 L  X+Q31
86 ;
87 QL1 = 270
88 LBL 1
89 QL1 = QL1 + 1
90 QL2 = QL11 * COS QL1
91 QL3 = QL11 * SIN QL1
92 QL2 = Q31 + QL2
93 QL3 = Q21 - QL3
94 L  X+QL2  Y-QL3 IC+1
95 CALL LBL 1 REP89
96 L  Y+Q21
97 QL1 = 0
98 LBL 2
99 QL1 = QL1 + 1
100 QL2 = QL11 * COS QL1
101 QL3 = QL11 * SIN QL1
102 QL2 = Q31 + QL2
103 QL3 = Q21 + QL3
104 L  X+QL2  Y+QL3 IC+1
105 CALL LBL 2 REP89
106 L  X-Q31
107 QL1 = 90
108 LBL 3
109 QL1 = QL1 + 1
110 QL2 = QL11 * COS QL1
111 QL3 = QL11 * SIN QL1
112 QL2 = Q31 - QL2
113 QL3 = Q21 + QL3
114 L  X-QL2  Y+QL3 IC+1
115 CALL LBL 3 REP89
116 L  Y-Q21
117 QL1 = 180
118 LBL 4
119 QL1 = QL1 + 1
120 QL2 = QL11 * COS QL1
121 QL3 = QL11 * SIN QL1
122 QL2 = Q31 - QL2
123 QL3 = Q21 - QL3
124 L  X-QL2  Y-QL3 IC+1
125 CALL LBL 4 REP89
126 L  X+0
127 CC  X+0  Y-QL13
128 CP  PA+0  Z-QL12 DR+
129 L  Z+15 R0 FMAX
130 M140 MB+50
131 M129
132 ;
133 FN 9: IF +0 EQU +0 GOTO LBL "end"
134 ;
135 LBL "aussen"
136 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
137 Q10 = Q108 * ( COS Q2 ) ;Berechne WZR-Korrektur Radius
138 Q11 = ( Q3 / 2 ) + Q10 ;Breite Y + WZR-Korrektur Radius
139 QL11 = Q5 + Q10
140 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;WZR-Korrektur Z
141 Q21 = ( Q3 / 2 ) - Q5 ;Mitte CC Y
142 Q31 = ( Q13 / 2 ) - Q5 ;Mitte CC X
143 QL13 = Q11 + Q108 ;Anfahrposition Y
144 QL12 = Q12 - 2 ;Anfahrposition Z
145 L  X+Q108  Y-QL13  Z+50 R0 FMAX
146 L  A-Q2  B+0  C+0 R0 FMAX ;Wichtig alle drei Rundachsen wegen TCPM ... AXIS SPAT
147 L  Z-QL12 R0 F AUTO
148 CC  X+0  Y-QL13
149 CP IPA+90  Z-Q12 DR+
150 L  X-Q31
151 ;
152 QL1 = 270
153 LBL 10
154 QL1 = QL1 - 1
155 QL2 = QL11 * COS QL1
156 QL3 = QL11 * SIN QL1
157 QL2 = Q31 - QL2
158 QL3 = Q21 - QL3
159 L  X-QL2  Y-QL3 IC-1
160 CALL LBL 10 REP89
161 L  Y+Q21
162 QL1 = 180
163 LBL 20
164 QL1 = QL1 - 1
165 QL2 = QL11 * COS QL1
166 QL3 = QL11 * SIN QL1
167 QL2 = Q31 - QL2
168 QL3 = Q21 + QL3
169 L  X-QL2  Y+QL3 IC-1
170 CALL LBL 20 REP89
171 L  X+Q31
172 QL1 = 90
173 LBL 30
174 QL1 = QL1 - 1
175 QL2 = QL11 * COS QL1
176 QL3 = QL11 * SIN QL1
177 QL2 = Q31 + QL2
178 QL3 = Q21 + QL3
179 L  X+QL2  Y+QL3 IC-1
180 CALL LBL 30 REP89
181 L  Y-Q21
182 QL1 = 0
183 LBL 40
184 QL1 = QL1 - 1
185 QL2 = QL11 * COS QL1
186 QL3 = QL11 * SIN QL1
187 QL2 = Q31 + QL2
188 QL3 = Q21 - QL3
189 L  X+QL2  Y-QL3 IC-1
190 CALL LBL 40 REP89
191 L  X+0
192 CC  X+0  Y-QL13
193 CP  PA+180  Z-QL12 DR+
194 L  Z+15 R0 FMAX
195 M140 MB+50
196 M129
197 ;
198 LBL "end"
199 LBL 0
200 END PGM 5090-DE MM