0  BEGIN PGM 51051_DE MM 
1  ;NC-Programm, um die Werkzeugbahn fuer das
2  ;Entgraten einer Passfedernut zu berechnen.
3  ;Dieses NC-Programm ist so aufgebaut, dass es
4  ;aus einem Bearbeitungsprogramm als Zyklus
5  ;gerufen wird. Die Definition der benoetigten
6  ;Parameter erfolgt in dem rufenden
7  ;Bearbeitungsprogramm. Somit muessen Sie an
8  ;diesem NC-Programm keine Aenderungen vornehmen.
9  ;
10 FN 18: SYSREAD Q1 = ID270 NR1 IDX1 ;Aktuelle X-Position auslesen
11 FN 18: SYSREAD Q2 = ID270 NR1 IDX2 ;Aktuelle Y-Position auslesen
12 Q5 = Q203 + ABS Q200 ;Sicherheitsabstand
13 Q6 = Q203 + ABS Q204 ;2. Sicherheitsabstand
14 CYCL DEF 7.0 NULLPUNKT
15 CYCL DEF 7.1 IX+Q1
16 CYCL DEF 7.2 IY+Q2
17 CYCL DEF 10.0 DREHUNG
18 CYCL DEF 10.1 IROT+Q374
19 ;Nutlage
20 Q7 = 0
21 FN 9: IF +Q367 EQU +0 GOTO LBL "END"
22 Q7 = ABS Q218 / 2
23 FN 9: IF +Q367 EQU +1 GOTO LBL "END"
24 Q7 = ( ABS Q218 - ABS Q219 ) / 2
25 FN 9: IF +Q367 EQU +2 GOTO LBL "END"
26 Q7 = NEG ( ABS Q218 - ABS Q219 ) / 2
27 FN 9: IF +Q367 EQU +3 GOTO LBL "END"
28 Q7 = NEG ABS Q218 / 2
29 LBL "END"
30 CYCL DEF 7.0 NULLPUNKT
31 CYCL DEF 7.1 IX+Q7
32 ;
33 Q10 = ( ABS Q218 - ABS Q219 ) / 2 ;X-MIN
34 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q219 / 2 ) )
35 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
36 Q13 = Q219 / 2 - Q108
37 L  X+0  Y+0  Z+Q6 R0 FMAX
38 L  Z+Q5 R0 FMAX
39 L  X+0  Y+0  Z+Q12 FQ207
40 APPR LCT  X+0  Y+Q13 R1 FQ207
41 L  X-Q10
42 Q20 = 90 ;Startwinkel
43 LBL 1
44 Q20 = Q20 + 1
45 Q21 = - Q10 + COS Q20 * Q13
46 Q22 = SIN Q20 * Q13
47 Q23 = SIN Q20 * Q219 / 2
48 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q23 ) )
49 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
50 L  X+Q21  Y+Q22  Z+Q12
51 CALL LBL 1 REP179
52 L  X+Q10
53 Q20 = - 90 ;Startwinkel
54 LBL 2
55 Q20 = Q20 + 1
56 Q21 = Q10 + COS Q20 * Q13
57 Q22 = SIN Q20 * Q13
58 Q23 = SIN Q20 * Q219 / 2
59 Q11 = SQRT ( SQ ( Q222 / 2 ) - SQ ( Q23 ) )
60 Q12 = Q203 - ( Q222 / 2 - Q11 ) - ABS Q201
61 L  X+Q21  Y+Q22  Z+Q12
62 CALL LBL 2 REP179
63 L  X+0
64 DEP LCT  X+0  Y+0 R1
65 ;
66 CYCL DEF 7.0 NULLPUNKT
67 CYCL DEF 7.1  X+0
68 CYCL DEF 7.2  Y+0
69 CYCL DEF 7.3  Z+0
70 CYCL DEF 10.0 DREHUNG
71 CYCL DEF 10.1  ROT+0
72 L  Z+Q6 R0 FMAX
73 END PGM 51051_DE MM