0  BEGIN PGM 8090-de MM 
1  ;Programm zum Erfassen von 
2  ;Koordinatenpunkten
3  ;
4  BLK FORM 0.1 Z  X+0  Y+0  Z-20
5  BLK FORM 0.2  X+100  Y+100  Z+0
6  ;
7  ;Schreibe BeginPGM ins protokoll
8  FN 16: F-PRINT TNC:\Database\BeginPGM.A / surface_data.txt
9  ;
10 ;Werkzeugaufruf Taster
11 TOOL CALL 501 Z
12 ;
13 ;Vorpositionieren
14 FN 0: Q1 =+0 ;STARTKOORDINATE IN X ZUM VORPOSITIONIEREN
15 FN 0: Q2 =+0.5 ;STARTKOORDINATE IN Y
16 LBL 1
17 FN 1: Q1 =+Q1 + +5 ;Neuer Wert in X=aktueller Wert+Schritt
18 TCH PROBE 0.0 BEZUGSEBENE Q3 Z-
19 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
20 ;
21 ;Schreibe Werte in das Protokoll
22 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
23 CALL LBL 1 REP18 ;18 Wiederholungen, letzte Koordinate X+95
24 FN 1: Q2 =+Q2 + +1 ;Schritt in Y
25 LBL 2
26 TCH PROBE 0.0 BEZUGSEBENE Q3 Z-
27 TCH PROBE 0.1  X+Q1  Y+Q2  Z+5
28 ;
29 ;Schreibe Werte in das Protokoll
30 FN 16: F-PRINT TNC:\Database\measure.A / surface_data.txt
31 FN 2: Q1 =+Q1 - +5 ;Schritt in X
32 CALL LBL 2 REP18 ;18 Wiederholungen, letzte Koordinate X+5
33 FN 1: Q2 =+Q2 + +1 ;Schritt in Y
34 CALL LBL 1 REP49 ;49 Wiederholungen, letzte Reihe Y+99,5
35 ;
36 ;Schreibe  EndPGM ins Protokoll
37 FN 16: F-PRINT TNC:\Database\ENDPGM.A / surface_data.txt
38 ;
39 ;Programm Ende
40 L  Z+100 R0 FMAX M30
41 END PGM 8090-de MM