0  BEGIN PGM 8125-de MM 
1  ;Werkstueckzaehler
2  ;In diesem Programm wird die Anzahl
3  ;der gefertigten Werkstuecke in
4  ;einer Tabelle gespeichert, so
5  ;dass die Werte auch erhalten
6  ;bleiben, wenn die Steuerung
7  ;heruntergefahren wird.
8  ;Bei Programmstart muss in der 
9  ;Tabelle Zeile 0 / Spalte Q1
10 ;der Wert 1 eingetragen sein.
11 ;Am Programmanfang tragen sie die 
12 ;Anzahl der gewuenschten 
13 ;Wiederholungen ein. Wenn das
14 ;Programm gestartet wird, wird die 
15 ;Anzahl der bisherigen Durchlaeufe
16 ;auf dem Bildschirm angezeigt.
17 ;Wenn die Anzahl der
18 ;programmierten Wiederholungen
19 ;erreicht ist wird auch dies auf
20 ;dem Bildschirm angezeigt, und
21 ;anschliessend wird der Wert
22 ;in der Tabelle auf 1 zurueck-
23 ;gesetzt.
24 ;
25 ;
26 ;Eingabe der gewuenschten Wiederholungen
27 Q10 = 8 ;ANZAHL DER WIEDERHOLUNGEN
28 ;
29 ;Oeffen der Tabelle
30 FN 26: TABOPEN TNC:\Database\81251-de.tab
31 ;Aktuellen Wert aus der Tabelle lesen
32 FN 28: TABREAD Q1 =0 /"Q1"
33 ;
34 FN 0: Q2 =+Q1 ;Wert kopieren
35 Q5 = Q1 - 1 ;Bisherige Anzahl berechnen
36 ;
37 ;Anzahl der bisherigen Wiederholungen anzeigen
38 FN 16: F-PRINT TNC:\Database\81252-de.a / Screen:
39 ;
40 Q1 = Q1 + 1 ;Zaehler weiter takten
41 ;
42 ;
43 ;Durchlauf der gewuenschten
44 ;Bearbeitung. Moeglich mit
45 ;PGM CALL, dann darf das gerufene
46 ;Programm kein M2 oder M30
47 ;enthalten
48 CALL PGM TNC:\Database\81254-de.h
49 STOP
50 ;
51 ;
52 ;Vergleich, ob die Anzahl der
53 ;Wiederholungen erreicht ist
54 FN 12: IF +Q2 LT +Q10 GOTO LBL 99
55 ;Anzeige, dass die Anzahl der 
56 ;Wiederholungen erreicht ist.
57 FN 16: F-PRINT TNC:\Database\81253-de.a / Screen:
58 ;
59 Q1 = 1 ;Zaehler zuruecksetzen
60 ;Wert des Zaehlers in die Tabelle schreiben
61 FN 27: TABWRITE 0 /"Q1" = Q1
62 ;Programmende
63 STOP
64 M30
65 ;
66 ;Sprungmarke, wenn weitere 
67 ;Wiederholungen noetig sind
68 LBL 99
69 ;Wert des Zaehlers in die Tabelle schreiben
70 FN 27: TABWRITE 0 /"Q1" = Q1
71 ;Programmende
72 M30
73 END PGM 8125-de MM