0  BEGIN PGM 82251_DE MM 
1  ;NC-Programm, um den Zaehler weiter zu
2  ;rechnen, die aktuelle Uhrzeit
3  ;auszulesen und mit der von Ihnen im Programm
4  ;8220_de.h definierten Zeit zu vergleichen.
5  ;Ist die von Ihnen definierte Zeit erreicht
6  ;oder ueberschritten, dann setzt die
7  ;Steuerung den Zaehler automatisch auf Null
8  ;zurueck.
9  ;
10 ;Wert im Zaehler um eins erhoehen
11 QR1 = QR1 + 1
12 ;
13 ;Aktuelle Zeit auslesen und im QS1 speichern
14 QS1 = SYSSTR( ID321 NR13 )
15 ;
16 ;Stunden aus dem QS1 separieren und im QS20 speichern
17 QS20 = SUBSTR( SRC_QS1 BEG0 LEN2 )
18 ;
19 ;Minuten aus dem QS1 separieren und im QS21 speichern
20 QS21 = SUBSTR( SRC_QS1 BEG3 LEN2 )
21 ;
22 ;String im QS20 in Zahl wandeln und im QL20 speichern (Stunden)
23 QL20 = TONUMB( SRC_QS20 )
24 ;
25 ;String aus QS21 in Zahl wandeln und im QL21 speichern (Minuten)
26 QL21 = TONUMB( SRC_QS21 )
27 ;
28 ;Pruefen ob Stunden zum Zuruecksetzen erreicht sind
29 FN 11: IF +QL20 GT +QR10 GOTO LBL "RESET"
30 FN 12: IF +QL20 LT +QR10 GOTO LBL "NOT_RESET"
31 ;
32 ;Pruefen ob Minuten zum Zuruecksetzen erreicht sind
33 FN 12: IF +QL21 LT +QR11 GOTO LBL "NOT_RESET"
34 ;
35 ;Zaehler zuruecksetzen
36 LBL "RESET"
37 QR1 = 0
38 ;
39 STOP
40 LBL "NOT_RESET"
41 END PGM 82251_DE MM