0  BEGIN PGM 8230_DE MM 
1  ;NC-Programm um an Bearbeitungspositionen, 
2  ;die in einer Punktetabelle definiert sind,
3  ;die exakte Z-Koordinate zu messen und diese
4  ;in die Tabelle einzutragen. Anschliessend
5  ;ist die Punktetabelle als Pattern definiert
6  ;und die Steuerung arbeitet an den Positionen
7  ;einen definierten Bearbeitungszyklus ab.
8  ;Die in der Tabelle eingetragene Z-Koordinate
9  ;definiert den Startpunkt des Zyklus, so dass
10 ;die im Zyklus definierte Tiefe sich immer
11 ;auf die vorab gemessene Z-Koordinate bezieht.
12 ;
13 BLK FORM 0.1 Z X-25 Y-25 Z-50
14 BLK FORM 0.2  X+25  Y+25  Z+0
15 ;
16 ;Messen
17 ;Werkzeugaufruf Tastsystem
18 TOOL CALL "TOUCH_PROBE" Z
19 ;
20 ;Tabelle oeffnen
21 FN 26: TABOPEN 82301_de.PNT
22 ;
23 Q52 = 5 ;ANZAHL DER ZU MESSENDEN POSITIONEN
24 CALL LBL "MEASURE" ;Unterprogrammaufruf Messen
25 ;
26 ;Bearbeiten
27 ;Werkzeugaufruf Bohrer
28 TOOL CALL "DRILL_D8.5" Z S9000 F2500
29 M3
30 CYCL DEF 200 BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-2    ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q395=+1    ;BEZUG TIEFE
31 SEL PATTERN "82301_de.PNT"
32 L  X+0  Y+0  Z+50 R0 FMAX
33 CYCL CALL PAT FMAX
34 ;
35 CALL LBL "SAFE" ;Sichere Position anfahren
36 ;
37 ;Programmende
38 M30
39 ;
40 ;Unterprogramme
41 ;Sichere Position anfahren
42 LBL "SAFE"
43 M140 MB MAX F9999
44 L  X+0  Y+0 R0 FMAX M91
45 LBL 0
46 ;
47 ;Unterprogramm Messen
48 LBL "MEASURE"
49 Q50 = 0 ;Erste Zeile
50 Q51 = Q52 - 1 ;Berechnung fuer Anzahl Wiederholungen
51 LBL "LOOP"
52 ;XY Koordinaten lesen fuer Messung
53 FN 28: TABREAD Q55 =Q50 /"X,Y"
54 TCH PROBE 427 MESSEN KOORDINATE ~
    Q263=+Q55  ;1. PUNKT 1. ACHSE ~
    Q264=+Q56  ;1. PUNKT 2. ACHSE ~
    Q261=+0    ;MESSHOEHE ~
    Q320=+5    ;SICHERHEITS-ABST. ~
    Q272=+3    ;MESSACHSE ~
    Q267=-1    ;VERFAHRRICHTUNG ~
    Q260=+15   ;SICHERE HOEHE ~
    Q281=+0    ;MESSPROTOKOLL ~
    Q288=+0    ;GROESSTMASS ~
    Q289=+0    ;KLEINSTMASS ~
    Q309=+0    ;PGM-STOP BEI FEHLER ~
    Q330=+0    ;WERKZEUG ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q531=+0    ;ANSTELLWINKEL
55 ;Messergebnis in Z in die Punktedatei speichern
56 FN 27: TABWRITE Q50 /"Z" = Q160
57 Q50 = Q50 + 1 ;Zeilennummer erhoehen
58 CALL LBL "LOOP" REPQ51
59 LBL 0
60 END PGM 8230_DE MM