0  BEGIN PGM 8235_DE MM 
1  ;NC-Programm um an Bearbeitungspositionen,
2  ;die in einer Punktetabelle definiert sind,
3  ;die exakte Z-Koordinate zu messen und diese
4  ;in die Tabelle einzutragen.
5  ;In diesem Beispielprogramm fuehrt die
6  ;Steuerung die Messroutine auf fuenf Flaechen
7  ;eines Wuerfels durch.
8  ;Anschliessend ist fuer jede Seite die
9  ;jeweilige Punktetabelle als Pattern definiert
10 ;und die Steuerung arbeitet an den Positionen
11 ;einen definierten Bearbeitungszyklus ab.
12 ;Die in der Tabelle eingetragene
13 ;Z-Koordinate definiert den Startpunkt des
14 ;Zyklus, so dass die im Zyklus definierte  
15 ;Tiefe sich immer auf die vorab gemessene
16 ;Z-Koordinate bezieht.
17 ;
18 BLK FORM 0.1 Z X-25 Y-25 Z-50
19 BLK FORM 0.2  X+25  Y+25  Z+0
20 ;
21 ;MESSEN
22 ;
23 ;Werkzeugaufruf Tastsystem
24 TOOL CALL "TOUCH_PROBE" Z
25 ;
26 ;Seite 1
27 PLANE RESET STAY ;Schwenken zuruecksetzen
28 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Nullpunktverschiebung
29 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
30 CALL LBL "SAFE"
31 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Bearbeitungsebene einschwenken
32 ;
33 ;Punktetabelle Seite 1 oeffnen 
34 FN 26: TABOPEN 82351.PNT
35 Q52 = 1 ;ANZAHL DER POSITIONEN
36 ;Aufruf Unterprogramm zum Messen
37 CALL LBL "MEASURE"
38 ;
39 ;Seite 2
40 PLANE RESET STAY ;Schwenken zuruecksetzen
41 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Nullpunktverschiebung
42 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
43 CALL LBL "SAFE"
44 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Bearbeitungsebene schwenken
45 ;
46 ;Punktetabelle Seite 2 oeffnen
47 FN 26: TABOPEN 82352.PNT
48 Q52 = 2 ;ANZAHL DER POSITIONEN
49 ;Aufruf Unterprogramm zum Messen
50 CALL LBL "MEASURE"
51 ;
52 ;Seite 3
53 PLANE RESET STAY ;Schwenken zuruecksetzen
54 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Nullpunktverschiebung
55 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
56 CALL LBL "SAFE"
57 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Bearbeitungsebene schwenken
58 ;
59 ;Punktetabelle Seite 3 oeffnen
60 FN 26: TABOPEN 82353.PNT
61 Q52 = 3 ;ANZAHL DER POSITIONEN
62 ;Aufruf Unterprogramm zum Messen
63 CALL LBL "MEASURE"
64 ;
65 ;Seite 4
66 PLANE RESET STAY ;Schwenken zuruecksetzen
67 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Nullpunktverschiebung
68 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
69 CALL LBL "SAFE"
70 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Bearbeitungsebene schwenken
71 ;
72 ;Punktetabelle Seite 4 offnen
73 FN 26: TABOPEN 82354.PNT
74 Q52 = 4 ;ANZAHL DER POSITIONEN
75 ;Aufruf Unterprogramm zum Messen
76 CALL LBL "MEASURE"
77 ;
78 ;Seite 5
79 PLANE RESET STAY ;Schwenken zuruecksetzen
80 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Nullpunktverschiebung
81 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
82 CALL LBL "SAFE"
83 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Bearbeitungsebene schwenken
84 ;
85 ;Punktetabelle Seite 5 oeffnen
86 FN 26: TABOPEN 82355.PNT
87 Q52 = 5 ;ANZAHL DER POSITIONEN
88 ;Aufruf Unterprogramm zum Messen
89 CALL LBL "MEASURE"
90 ;
91 ;BEARBEITEN
92 ;
93 ;Werkzeugaufruf Bohrer
94 TOOL CALL "DRILL_D8.5" Z S9000 F2500
95 M3
96 CYCL DEF 200 BOHREN ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q201=-2    ;TIEFE ~
    Q206= AUTO ;VORSCHUB TIEFENZ. ~
    Q202=+5    ;ZUSTELL-TIEFE ~
    Q210=+0    ;VERWEILZEIT OBEN ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST. ~
    Q211=+0    ;VERWEILZEIT UNTEN ~
    Q395=+1    ;BEZUG TIEFE
97 ;
98 ;Seite 1
99 PLANE RESET STAY ;Schwenken zuruecksetzen
100 TRANS DATUM AXIS  X+0  Y+0  Z+0 ;Nullpunktverschiebung
101 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
102 CALL LBL "SAFE"
103 PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN FMAX ;Bearbeitungsebene schwenken
104 ;
105 ;Definition der Punktetabelle Seite 1 als Punktemuster
106 SEL PATTERN "82351.PNT"
107 ;Aufruf Unterprogramm zur Bearbeitung
108 CALL LBL "MACHINING"
109 ;
110 ;Seite 2
111 PLANE RESET STAY ;Schwenken zuruecksetzen
112 TRANS DATUM AXIS  X+25  Y-14.1421  Z-10.8579 ;Nullpunktverschiebung
113 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
114 CALL LBL "SAFE"
115 PLANE SPATIAL SPA+90 SPB+0 SPC+90 TURN FMAX ;Bearbeitungsebene schwenken
116 ;
117 ;Definition der Punktetabelle Seite 2 als Punktemuster
118 SEL PATTERN "82352.PNT"
119 ;Aufruf Unterprogramm zur Bearbeitung
120 CALL LBL "MACHINING"
121 ;
122 ;Seite 3
123 PLANE RESET STAY ;Schwenken zuruecksetzen
124 TRANS DATUM AXIS  X+14.1421  Y+25  Z-10.8579 ;Nullpunkverschiebung
125 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
126 CALL LBL "SAFE"
127 PLANE SPATIAL SPA+90 SPB+0 SPC-180 TURN FMAX ;Bearbeitungsebene schwenken
128 ;
129 ;Definition der Punktetabelle Seite 3 als Punktemuster
130 SEL PATTERN "82353.PNT"
131 ;Aufruf Unterprogramm zur Bearbeitung
132 CALL LBL "MACHINING"
133 ;
134 ;Seite 4
135 PLANE RESET STAY ;Schwenken zuruecksetzen
136 TRANS DATUM AXIS  X-14.1421  Y-25  Z-10.8579 ;Nullpunktverschiebung
137 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
138 CALL LBL "SAFE"
139 PLANE SPATIAL SPA+90 SPB+0 SPC+0 TURN FMAX ;Bearbeitungseben schwenken
140 ;
141 ;Definition der Punktetabelle Seite 4 als Punktemuster
142 SEL PATTERN "82354.PNT"
143 ;Aufruf Unterprogramm zur Bearbeitung
144 CALL LBL "MACHINING"
145 ;
146 ;Seite 5
147 PLANE RESET STAY ;Schwenken zuruecksetzen
148 ;Nullpunktverschiebung
149 TRANS DATUM AXIS  X-25  Y+14.1421  Z-10.8579 ;Nullpunktverschiebung
150 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
151 CALL LBL "SAFE"
152 PLANE SPATIAL SPA+90 SPB+0 SPC-90 TURN FMAX ;Bearbeitungsebene einschwenken
153 ;
154 ;Definition der Punktetabelle Seite 5 als Punktemuster
155 SEL PATTERN "82355.PNT"
156 ;Aufruf Unterprogramm zur Bearbeitung
157 CALL LBL "MACHINING"
158 ;
159 ;Aufruf Unterprogramm zum Anfahren einer sicheren Position
160 CALL LBL "SAFE"
161 PLANE RESET TURN FMAX ;Schwenken zuruecksetzen
162 ;
163 ;Programmende
164 M30
165 ;
166 ;Unterprogramme
167 ;Fahren auf eine maschinenabhaengige sichere Position
168 LBL "SAFE"
169 M140 MB MAX F9999
170 L  Z+0 R0 FMAX M91
171 L  X+0  Y+0 R0 FMAX M91
172 LBL 0
173 ;
174 ;Messen
175 LBL "MEASURE"
176 Q50 = 0 ;Erste Zeile
177 Q51 = Q52 - 1 ;Berechnung fuer Anzahl Wiederholungen
178 LBL "LOOP"
179 ;XY Koordinaten lesen fuer Messung
180 FN 28: TABREAD Q55 =Q50 /"X,Y"
181 TCH PROBE 427 MESSEN KOORDINATE ~
    Q263=+Q55  ;1. PUNKT 1. ACHSE ~
    Q264=+Q56  ;1. PUNKT 2. ACHSE ~
    Q261=+0    ;MESSHOEHE ~
    Q320=+5    ;SICHERHEITS-ABST. ~
    Q272=+3    ;MESSACHSE ~
    Q267=-1    ;VERFAHRRICHTUNG ~
    Q260=+15   ;SICHERE HOEHE ~
    Q281=+0    ;MESSPROTOKOLL ~
    Q288=+0    ;GROESSTMASS ~
    Q289=+0    ;KLEINSTMASS ~
    Q309=+0    ;PGM-STOP BEI FEHLER ~
    Q330=+0    ;WERKZEUG ~
    Q498=+0    ;WERKZEUG UMKEHREN ~
    Q531=+0    ;ANSTELLWINKEL
182 ;Messergebnis in Z in die Punktedatei speichern
183 FN 27: TABWRITE Q50 /"Z" = Q160
184 Q50 = Q50 + 1 ;Zeilennummer erhoehen
185 CALL LBL "LOOP" REPQ51
186 LBL 0
187 ;
188 ;Bearbeitung
189 LBL "MACHINING"
190 L  X+0  Y+0  Z+50 R0 FMAX ;Vorpositionieren
191 CYCL CALL PAT FMAX ;Zyklus an den Positionen der Punktetabelle aufrufen
192 LBL 0
193 END PGM 8235_DE MM