0  BEGIN PGM 9035_de MM 
1  ;NC-Programm, um den Dateinamen
2  ;automatisch zu ermitteln und
3  ;mittels Zyklus ins Werkstueck
4  ;zu gravieren.
5  ;Die Steuerung ruft eine
6  ;Maskendatei auf. Diese schreibt
7  ;den Dateipfad in eine Textdatei.
8  ;Im Anschluss ruft die Steuerung
9  ;ein Programm, mit dem sie aus
10 ;dem Dateipfad den Programmnamen
11 ;selektiert. Den Dateinamen 
12 ;speichert die Steuerung im QS1.
13 ;Diesen uebernimmt sie beim
14 ;Ruecksprung in dieses Programm
15 ;und verwendet ihn im
16 ;Gravierzyklus 225.
17 ;Wenn die drei verwendeten Dateien
18 ;nicht im selben Verzeichnis liegen,
19 ;muessen Sie die Pfadangaben in
20 ;Aufrufen anpassen!
21 ;
22 ;!WICHTIG! Das Pogramm laeuft
23 ;nicht im Programmtest, da dort
24 ;das Kopieren einer Textdatei
25 ;in ein NC-Programm nicht erlaubt
26 ;ist!
27 ;
28 BLK FORM 0.1 Z  X+0  Y+0  Z-20
29 BLK FORM 0.2  X+100  Y+100  Z+0
30 ;
31 ;Werkzeugaufruf Gravierwerkzeug
32 TOOL CALL 151 Z S6000
33 M3
34 ;
35 L  Z+100 R0 FMAX
36 ;
37 ;Inhalt der Datei "mask" in die
38 ;Datei "File" schreiben. Dabei
39 ;wird durch die Syntax der
40 ;Programmname eingetragen.
41 FN 16: F-PRINT mask.a / FILE.a
42 ;
43 ;Programm zum Bilden des
44 ;Textstrings aufrufen
45 CALL PGM 90351_de.H
46 ;
47 ;
48 ;Dateiname, der im QS1 steht
49 ;gravieren
50 CYCL DEF 225 GRAVIEREN ~
    QS500= QS1     ;GRAVIERTEXT ~
    Q513=+10   ;ZEICHENHOEHE ~
    Q514=+0    ;FAKTOR ABSTAND ~
    Q515=+0    ;SCHRIFTART ~
    Q516=+0    ;TEXTANORDNUNG ~
    Q374=+0    ;DREHLAGE ~
    Q517=+50   ;KREISRADIUS ~
    Q207=+500  ;VORSCHUB FRAESEN ~
    Q201=-0.3  ;TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
51 ;
52 ;Zyklus am Startpunkt aufrufen
53 L  X+20  Y+40 R0 FMAX M99
54 ;
55 ;Freifahren
56 L  Z+100 R0 FMAX
57 ;
58 ;Programmende
59 M30
60 END PGM 9035_de MM